pearl-pmsco-import.ipf

Go to the documentation of this file.

#pragma TextEncoding = "UTF-8"
#pragma rtGlobals=3     // Use modern global access method and strict wave access.
#pragma IgorVersion = 6.2
#pragma ModuleName = PearlPmscoImport
 
// copyright (c) 2018-25 Paul Scherrer Institut
//
// Licensed under the Apache License, Version 2.0 (the "License");
//   you may not use this file except in compliance with the License.
//   You may obtain a copy of the License at
//   http:///www.apache.org/licenses/LICENSE-2.0
//
// Please acknowledge the use of this code.
 
 
 
 
function /s pmsco_save_scan(pathname, filename, energy, theta, phi, alpha, intensity, sigma, [sdfr])
    string pathname
    string filename
    string energy
    string theta
    string phi
    string alpha
    string intensity
    string sigma
    dfref sdfr
 
    //string fileext
    //fileext = StringFromList(ItemsInList(filename, ".") - 1, filename, ".")
    
    dfref savedf = GetDataFolderDFR()
    dfref tempdf = NewFreeDataFolder()
 
    if (ParamIsDefault(sdfr))
        dfref sdfr = savedf
    endif
    SetDataFolder sdfr
    wave w_intensity = $intensity
    string wavenames = ""
    
    wavenames = save_scan_helper("w_energy", energy, w_intensity, tempdf, wavenames)
    wavenames = save_scan_helper("w_theta", theta, w_intensity, tempdf, wavenames)
    wavenames = save_scan_helper("w_phi", phi, w_intensity, tempdf, wavenames)
    wavenames = save_scan_helper("w_alpha", alpha, w_intensity, tempdf, wavenames)
    wavenames = save_scan_helper("w_intensity", intensity, w_intensity, tempdf, wavenames)
    wavenames = save_scan_helper("w_sigma", sigma, w_intensity, tempdf, wavenames)
    
    setdatafolder tempdf
    save /b /g /m="\n" /p=$pathname wavenames as filename
    setdatafolder savedf
end
 
static function /s save_scan_helper(destname, value, template, destdfr, wavenames)
    string destname
    string value
    wave template
    dfref destdfr
    string wavenames
    
    variable err = 0
    if (strlen(value) > 0)
        if (exists(value) == 1)
            duplicate $value, destdfr:$destname
            wave /sdfr=destdfr w=$destname
        else
            duplicate template, destdfr:$destname
            wave /sdfr=destdfr w=$destname
            variable numval = str2num(value)
            string msg
            if (numtype(numval) == 0)
                w = numval
            //elseif (cmpstr(value[0,0], "%") == 0)
            else
                strswitch(value)
                    case "x":
                        w = DimOffset(template, 0) + DimDelta(template, 0) * p
                        break
                    case "y":
                        w = DimOffset(template, 1) + DimDelta(template, 1) * q
                        break
                    case "z":
                        w = DimOffset(template, 2) + DimDelta(template, 2) * r
                        break
                    case "t":
                        w = DimOffset(template, 3) + DimDelta(template, 3) * s
                        break
                    default:
                        err = 1
                        sprintf msg, "invalid %s argument", StringFromList(1, destname, "_")
                endswitch
            endif
        endif
        if (err == 0)
            wavenames = AddListItem(destname, wavenames, ";", inf)
            variable npts = DimSize(w, 0) * max(DimSize(w, 1), 1) * max(DimSize(w, 2), 1) * max(DimSize(w, 3), 1)
            Redimension /n=(npts) w
        else
            abort msg       
        endif
    endif
    return wavenames
end
 
function /s load_pmsco_scan(pathname, filename, [is_modulation, quiet])
    string pathname // name of a symbolic path
    string filename
    variable is_modulation
    variable quiet
    
    if (ParamIsDefault(quiet))
        quiet = 0
    endif
 
    loadwave /p=$pathname /a /g /o /q filename
 
    if (ParamIsDefault(is_modulation))
        is_modulation = StringMatch(s_filename, "*.modf.*")
    else
        is_modulation = is_modulation > 0
    endif
 
    string fileext
    string waves = ""
    if (v_flag > 0)
        fileext = StringFromList(ItemsInList(s_filename, ".") - 1, s_filename, ".")
        variable nw = ItemsInList(s_wavenames)
        variable iw
        string sw1, sw2
        for (iw = 0; iw < nw; iw += 1)
            sw1 = StringFromlist(iw, s_wavenames)
            strswitch(fileext[iw])
                case "e":
                    sw2 = "en"
                    break
                case "t":
                    sw2 = "th"
                    break
                case "p":
                    sw2 = "ph"
                    break
                case "a":
                    sw2 = "al"
                    break
                case "i":
                    if (is_modulation)
                        sw2 = "mo"
                    else
                        sw2 = "in"
                    endif
                    break
                case "s":
                    sw2 = "si"
                    break
            endswitch
            duplicate /o $sw1, $sw2
            killwaves /z $sw1
            waves = AddListItem(sw2, waves, ",", inf)
        endfor
        
        // Sort {en,th,ph, al} en,th,ph,al,int,sig
        
        if (!quiet)
            print "load_pmsco_scan ",  s_filename, ": ", waves
        endif
        
        return s_filename
    else
        return ""
    endif
end
 
function /s load_pmsco_result(pathname, filename, [quiet])
    string pathname // name of a symbolic path
    string filename
    variable quiet
    
    if (ParamIsDefault(quiet))
        quiet = 0
    endif
    
    if (quiet)
        loadwave /p=$pathname /a /w /g /o /q filename
    else
        loadwave /p=$pathname /a /w /g /o filename
    endif
    
    if (v_flag > 0)
        return s_filename
    else
        return ""
    endif
end
 
 
function /s pmsco_load_xyz(pathname, filename)
    string pathname
    string filename
 
    string cis = "N=at;N=xx;N=yy;N=zz;"
    LoadWave /A /B=cis /J /K=0 /L={0, 2, 0, 0, 0} /V={" ", " ", 0, 0} /O /P=$pathname filename
    wave /t at
    at = unpadstring(at, 32)
end
 
function pmsco_load_alm(pathname, filename, wname)
    string pathname
    string filename
    string wname
    
    variable fid
    if (strlen(pathname) > 0)
        HDF5OpenFile /P=pathname /R /Z fid as filename
    else
        HDF5OpenFile /R /Z fid as filename
    endif
    
    if (v_flag == 0)
        HDF5LoadData /N=$wname /O /Q /Z fid, "alm"
        HDF5CloseFile fid
        
        wave alm_r = $(wname + "_r")
        wave alm_i = $(wname + "_i")
        make /c /n=(dimsize(alm_r, 0), dimsize(alm_r, 1)) /o $wname
        wave /c alm = $wname
        alm = cmplx(alm_r, alm_i)
        variable lmax = (dimsize(alm, 0) - 1) * 2
        setscale /i x 0, lmax, "l", alm, alm_r, alm_i
        setscale /i y -lmax, lmax, "m", alm, alm_r, alm_i
    endif
end