add musrfitConfig.cmake, etc. for musrfit.

CMakeLists.txt

@@ -448,6 +448,35 @@ message("")
 message("-------------------------------------------------------------------------")
 message("")
 
+#--- generate and install cmake package config files --------------------------
+include(CMakePackageConfigHelpers)
+
+configure_package_config_file(
+  ${CMAKE_SOURCE_DIR}/cmake/musrfitConfig.cmake.in
+  ${CMAKE_CURRENT_BINARY_DIR}/musrfitConfig.cmake
+  INSTALL_DESTINATION lib/cmake/musrfit
+)
+
+write_basic_package_version_file(
+  ${CMAKE_CURRENT_BINARY_DIR}/musrfitConfigVersion.cmake
+  VERSION ${PROJECT_VERSION}
+  COMPATIBILITY AnyNewerVersion
+)
+
+install(
+  EXPORT musrfitTargets
+  FILE musrfitTargets.cmake
+  NAMESPACE musrfit::
+  DESTINATION lib/cmake/musrfit
+)
+
+install(
+  FILES
+    ${CMAKE_CURRENT_BINARY_DIR}/musrfitConfig.cmake
+    ${CMAKE_CURRENT_BINARY_DIR}/musrfitConfigVersion.cmake
+  DESTINATION lib/cmake/musrfit
+)
+
 #--- cpack specific info ......................................................
 file(TO_NATIVE_PATH ${PROJECT_SOURCE_DIR} PROJECT_SOURCE_DIR_NATIVE)
 file(TO_NATIVE_PATH ${PROJECT_BINARY_DIR} PROJECT_BINARY_DIR_NATIVE)

cmake/musrfitConfig.cmake.in

@@ -0,0 +1,15 @@
+# musrfitConfig.cmake.in
+# CMake package configuration template for musrfit.
+# Generated by configure_package_config_file().
+
+@PACKAGE_INIT@
+
+include(CMakeFindDependencyMacro)
+
+find_dependency(ROOT REQUIRED COMPONENTS Gui MathMore Minuit2 XMLParser)
+find_dependency(Boost REQUIRED COMPONENTS filesystem)
+find_dependency(GSL REQUIRED)
+
+include("${CMAKE_CURRENT_LIST_DIR}/musrfitTargets.cmake")
+
+check_required_components(musrfit)

src/CMakeLists.txt

@@ -86,7 +86,11 @@ target_include_directories(musrfit
     $<BUILD_INTERFACE:${CMAKE_BINARY_DIR}/src>
     $<BUILD_INTERFACE:${CMAKE_SOURCE_DIR}/src/include>
 )
-target_link_libraries(musrfit ${ROOT_LIBRARIES} ${MUSRFIT_LIBS})
+if (OpenMP_CXX_FOUND)
+  target_link_libraries(musrfit ${ROOT_LIBRARIES} ${MUSRFIT_LIBS} OpenMP::OpenMP_CXX)
+else ()
+  target_link_libraries(musrfit ${ROOT_LIBRARIES} ${MUSRFIT_LIBS})
+endif (OpenMP_CXX_FOUND)
 
 add_executable(musrFT musrFT.cpp)
 target_compile_options(musrFT BEFORE PRIVATE "-DHAVE_CONFIG_H" "${HAVE_GIT_REV_H}")

src/classes/CMakeLists.txt

@@ -201,18 +201,18 @@ if (OpenMP_FOUND)
   set(DependOnLibs ${DependOnLibs} OpenMP::OpenMP_CXX)
 endif (OpenMP_FOUND)
 
-target_link_libraries(PUserFcnBase ${ROOT_LIBRARIES})
-target_link_libraries(PRgeHandler ${Boost_LIBRARIES} ${ROOT_LIBRARIES})
-target_link_libraries(PMusr ${Boost_LIBRARIES} ${DependOnLibs})
+target_link_libraries(PUserFcnBase PRIVATE ${ROOT_LIBRARIES})
+target_link_libraries(PRgeHandler PRIVATE ${Boost_LIBRARIES} ${ROOT_LIBRARIES})
+target_link_libraries(PMusr PRIVATE ${Boost_LIBRARIES} ${DependOnLibs})
 
 #--- install PUserFcnBase solib -----------------------------------------------
-install(TARGETS PUserFcnBase DESTINATION lib)
+install(TARGETS PUserFcnBase EXPORT musrfitTargets DESTINATION lib)
 
 #--- install PRgeHandler solib -----------------------------------------------
-install(TARGETS PRgeHandler DESTINATION lib)
+install(TARGETS PRgeHandler EXPORT musrfitTargets DESTINATION lib)
 
 #--- install PMusr solib ------------------------------------------------------
-install(TARGETS PMusr DESTINATION lib)
+install(TARGETS PMusr EXPORT musrfitTargets DESTINATION lib)
 
 #--- install root pcm's and rootmaps ------------------------------------------
 install(

src/external/MuSR_software/Class_MuSR_PSI/CMakeLists.txt

@@ -28,7 +28,7 @@ set_target_properties(Class_MuSR_PSI
 )
 
 #--- install Class_MuSR_PSI solib ---------------------------------------------
-install(TARGETS Class_MuSR_PSI DESTINATION lib)
+install(TARGETS Class_MuSR_PSI EXPORT musrfitTargets DESTINATION lib)
 
 #--- install MuSR_td_PSI_bin header -------------------------------------------
 install(FILES MuSR_td_PSI_bin.h DESTINATION include)

src/external/MusrRoot/CMakeLists.txt

@@ -46,7 +46,7 @@ set_target_properties(TMusrRunHeader
 target_link_libraries(TMusrRunHeader ${ROOT_LIBRARIES})
 
 #--- install TMusrRunHeader solib ---------------------------------------------
-install(TARGETS TMusrRunHeader DESTINATION lib)
+install(TARGETS TMusrRunHeader EXPORT musrfitTargets DESTINATION lib)
 
 #--- install root pcm's and rootmaps ------------------------------------------
 install(

src/external/TLemRunHeader/CMakeLists.txt

@@ -57,7 +57,7 @@ target_include_directories(
 target_link_libraries(TLemRunHeader ${ROOT_LIBRARIES})
 
 #--- install TLemRunHeader solib ----------------------------------------------
-install(TARGETS TLemRunHeader DESTINATION lib)
+install(TARGETS TLemRunHeader EXPORT musrfitTargets DESTINATION lib)
 
 #--- install root pcm's and rootmaps ------------------------------------------
 install(

src/external/mud/src/CMakeLists.txt

@@ -27,7 +27,7 @@ set_target_properties(mud
 )
 
 #--- install mud solib --------------------------------------------------------
-install(TARGETS mud DESTINATION lib) 
+install(TARGETS mud EXPORT musrfitTargets DESTINATION lib)
 
 #--- install mud header -------------------------------------------------------
 install(FILES mud.h DESTINATION include)

src/external/nexus/CMakeLists.txt

@@ -34,10 +34,10 @@ else (HAVE_HDF4)
   set(HDF_LIBS ${HDF5_LIBRARIES})
 endif (HAVE_HDF4)
 message(STATUS "as35> HDF_LIBS: ${HDF_LIBS}")
-target_link_libraries(PNeXus ${HDF_LIBS} ${ROOT_LIBRARIES})
+target_link_libraries(PNeXus PRIVATE ${HDF_LIBS} ${ROOT_LIBRARIES})
 
 #--- install PNeXus solib -----------------------------------------------------
-install(TARGETS PNeXus DESTINATION lib)
+install(TARGETS PNeXus EXPORT musrfitTargets DESTINATION lib)
 
 #--- install PNeXus header ----------------------------------------------------
 install(FILES PNeXus.h DESTINATION include)