if ($?tcsh) then
	set modules_shell="tcsh"
else
	set modules_shell="csh"
endif
set exec_prefix = "${PMODULES_HOME}/bin"

set prefix=""
set postfix=""

if ( $?histchars ) then
  set histchar = `echo $histchars | cut -c1`
  set _histchars = $histchars

  set prefix  = 'unset histchars;'
  set postfix = 'set histchars = $_histchars;'
else
  set histchar = \!
endif

if ($?prompt) then
  set prefix  = "$prefix"'set _prompt="$prompt";set prompt="";'
  set postfix = "$postfix"'set prompt="$_prompt";unset _prompt;'
endif

if ($?noglob) then
  set prefix  = "$prefix""set noglob;"
  set postfix = "$postfix""unset noglob;"
endif
set postfix = "set _exit="'$status'"; $postfix; test 0 = "'$_exit;'

alias module $prefix'eval `'$exec_prefix'/modulecmd '$modules_shell' '$histchar'*`; '$postfix
unset exec_prefix
unset prefix
unset postfix

setenv MODULEPATH
if (! $?DefaultGroups ) then
   setenv DefaultGroups 'Tools Programming'
endif
foreach group ( ${DefaultGroups} )
  if ( "${MODULEPATH}" == "" ) then
    setenv MODULEPATH "${PMODULES_ROOT}/${group}/modulefiles"
  else
    setenv MODULEPATH "${MODULEPATH}:${PMODULES_ROOT}/${group}/modulefiles"
  endif
end

if (! $?LOADEDMODULES ) then
  setenv LOADEDMODULES ""
endif