#
# SoC Plot Configuration File for gnuplot.
#
# Command line syntax:
#   $> gnuplot -persist -e "datafile='socResultPhi_2015-05-11_16:32:09.txt'" plot.cfg
# 
# Note: If the data file doesn't exist, the script will abort at the plot command.
#
# Author: Andreas Isenegger, Bitcontrol GmbH, Switzerland
# Last Edit: 28-May-2015
# Copyright: 2015, Paul Scherrer Institute, Switzerland, all rights reserved. 
#

reset

### Plot deviation in function of Phi to a window
# Makes plot window persisting, enables greek letters, sets title
windowTitle = sprintf("SoC Application - gnuplot of data in %s", datafile)
set terminal x11 0 persist enhanced title windowTitle
set title 'Sphere of Confusion'
set xlabel '{/Symbol F} [deg]'
set ylabel 'Deviation [nm]'
plot datafile using 3:4 with linespoints title "X = f({/Symbol F})", \
     datafile using 3:5 with linespoints title "Y = f({/Symbol F})", \
     datafile using 3:6 with linespoints title "Z = f({/Symbol F})"

### Plot deviation in function of Phi to a file
set terminal png
set output datafile.".XYZ.png"
plot datafile using 3:4 with linespoints title "X = f({/Symbol F})", \
     datafile using 3:5 with linespoints title "Y = f({/Symbol F})", \
     datafile using 3:6 with linespoints title "Z = f({/Symbol F})"

### Plot X/Y coordinates in function of Phi to another window
# Makes plot window persisting, enables greek letters, sets title
set terminal x11 1 persist enhanced title windowTitle
set xlabel 'X direction [nm]'
set ylabel 'Y direction [nm]'
plot datafile using 4:5 with linespoints title "X/Y = f({/Symbol F})"

### Plot X/Y coordinates in function of Phi to another file
set terminal png
set output datafile.".XvsY.png"
plot datafile using 4:5 with linespoints title "X/Y = f({/Symbol F})"