#
# SoC Plot Configuration File for gnuplot.
#
# Command line syntax:
#   $> gnuplot -persist -e "datafile='socResultChi_2015-05-11_16:32:09.txt'" plot.cfg
# 
# Note: If the data file doesn't exist, the script will abort at the plot command.
#
# Author: Andreas Isenegger, Bitcontrol GmbH, Switzerland
# Last Edit: 02-Jul-2015
# Copyright: 2015, Paul Scherrer Institute, Switzerland, all rights reserved. 
#

reset

### Plot deviation in function of Chi to a window
# Makes plot window persisting, enables greek letters, sets title
windowTitle = sprintf("SoC Application - gnuplot of data in %s", datafile)
set terminal x11 0 persist enhanced title windowTitle
set title 'Sphere of Confusion'
set xlabel '{/Symbol C} [deg]'
set ylabel 'Deviation [nm]'
plot datafile using 1:4 with points title "X = f({/Symbol C})", \
     datafile using 1:5 with points title "Y = f({/Symbol C})", \
     datafile using 1:6 with points title "Z = f({/Symbol C})"

### Plot deviation in function of Chi to a file
set terminal png
set output datafile.".XYZ.png"
plot datafile using 1:4 with points title "X = f({/Symbol C})", \
     datafile using 1:5 with points title "Y = f({/Symbol C})", \
     datafile using 1:6 with points title "Z = f({/Symbol C})"

### Plot Z/Y coordinates in function of Chi to another window
# Makes plot window persisting, enables greek letters, sets title
set terminal x11 1 persist enhanced title windowTitle
set xlabel 'Z direction [nm]'
set ylabel 'Y direction [nm]'
plot datafile using 6:5 with linespoints title "Z/Y = f({/Symbol C})"

### Plot Z/Y coordinates in function of Chi to another file
set terminal png
set output datafile.".ZvsY.png"
plot datafile using 6:5 with linespoints title "Z/Y = f({/Symbol C})"