Build Packages / build:portable:linux-x86_64:nocuda (push) Successful in 16m43s
Build Packages / build:jfjoch:ubuntu2404:nocuda (push) Successful in 28m46s
Build Packages / build:jfjoch:rocky8:cuda-sls9 (push) Successful in 32m5s
Build Packages / build:jfjoch:rocky9:cuda (push) Successful in 39m44s
Build Packages / build:portable:macos-arm64:nocuda (push) Successful in 5m7s
Build Packages / Create release (push) Successful in 8s
Build Packages / Build documentation (push) Successful in 49s
Build Packages / build:portable:linux-x86_64:cuda (push) Successful in 22m30s
Build Packages / build:jfjoch:rocky8:nocuda (push) Successful in 31m54s
Build Packages / build:rugnux:linux-aarch64:cuda (push) Successful in 11m29s
Build Packages / build:portable:windows-x86_64:nocuda (push) Successful in 23m51s
Build Packages / build:jfjoch:ubuntu2204:nocuda (push) Successful in 26m7s
Build Packages / build:jfjoch:ubuntu2204:cuda (push) Successful in 29m38s
Build Packages / build:portable:windows-x86_64:cuda (push) Successful in 28m6s
Build Packages / HDF5 consumer tests (DIALS, XDS) (push) Successful in 29m44s
Build Packages / build:jfjoch:rocky9:nocuda (push) Successful in 33m22s
Build Packages / Generate python client (push) Successful in 47s
Build Packages / build:jfjoch:rocky9:cuda-sls9 (push) Successful in 34m6s
Build Packages / Unit tests (push) Successful in 1h2m47s
Build Packages / build:jfjoch:rocky8:cuda (push) Successful in 35m59s
Build Packages / build:jfjoch:ubuntu2404:cuda (push) Successful in 34m8s
Build Packages / Validation Battery (push) Successful in 38m31s
* Rugnux: Refinement several times faster, one protocol on the CPU and the GPU, parts of it on the Apple GPU; its random draws are the same on every platform. * Rugnux: Refinement follows common practice: the free set decides only the restraint weights and the displacement model (isotropic, TLS or anisotropic, by Hamilton's test), everything else is decided on the working set; lower R-free for placed and predicted models. * Rugnux: Restraint dictionaries via `--restraints` (or among the inputs) and more built-in ligands; a model whose space group is a subgroup of the data's is refined in its own group; reflections plus a model select `--mode refine` on their own. * Rugnux: `-C` fixes the crystal system on the axes as typed; `-S` alone fixes the space group only, the cell is still found and reduced; a space group or cell stored in the input file is ignored, with a line in the log. * Rugnux: More reliable multi-sweep merging; `--mode scale` merges several stills runs as one; `_plot.txt` and the report name each input; a second crystal form is reported for stills given a cell. * jfjoch_broker (experimental): Live Rugnux on FPGA detectors (JUNGFRAU) takes the same path as a DECTRIS stream, rotation and serial alike, model step included, with analysis threads per GPU; frames waiting for the analysis can be viewed; no host stage drops a frame - a source faster than the analysis is held at the card. * jfjoch_broker: Summation of more than 256 frames per image is split between the card and the host (`summation_mode` is then `hybrid`), and live Rugnux runs on such collections; pedestal runs take a receiver of their own. * jfjoch_broker (experimental): `stills_downsample` analyses 1 of every N serial images (chosen by a hash; the first 2000 all; the others written without analysis; reset to 1 by `/initialize`); `max_spot_count` left out means 250 for per-image indexing and up to 1000 for live stills; the live status gives the merge before the model work, the fitted resolution and the anomalous peak height of each unexplained blob. * jfjoch_broker: Without a `pcie` entry the broker runs on a mock of the card instead of the HLS simulation; its spot, ROI and azimuthal results are zero then. * Web frontend: Redesigned Rugnux live page; Vite 8, TypeScript 6, Mol* 5.13 and dependency security updates. * Tools: `jfjoch_fpga_stills_test` measures live stills on the cards with a stored dataset; `jfjoch_fpga_test` loses the HLS-simulation option. * Other: FFTW no longer fetched or linked (the CPU FFT indexer keeps the name `FFTW`); PCIe driver now GPL-2.0-or-later and third-party notices complete; several crash fixes. Reviewed-on: #98 Co-authored-by: Filip Leonarski <filip.leonarski@psi.ch>
157 lines
6.7 KiB
Plaintext
157 lines
6.7 KiB
Plaintext
// SPDX-FileCopyrightText: 2026 Filip Leonarski, Paul Scherrer Institute <filip.leonarski@psi.ch>
|
|
// SPDX-License-Identifier: GPL-3.0-only
|
|
|
|
#import <Metal/Metal.h>
|
|
|
|
#include "SideChainFieldMetal.h"
|
|
|
|
#include <algorithm>
|
|
#include <atomic>
|
|
#include <cstdint>
|
|
#include <cstring>
|
|
#include <limits>
|
|
#include <string>
|
|
|
|
#include "../../common/CUDAWrapper.h" // gpus_are_hidden
|
|
#include "../../common/JFJochException.h"
|
|
|
|
// The kernel's source, SideChainFieldMetal.metal, copied in at configure time (CMakeLists.txt).
|
|
extern const char *const side_chain_field_metal_source;
|
|
|
|
namespace {
|
|
|
|
std::atomic<size_t> states_on_gpu{0};
|
|
|
|
static_assert(sizeof(FieldAtom) == 6 * 4, "the kernel's Atom is six words");
|
|
|
|
struct Kernel {
|
|
id<MTLDevice> device = nil; // nil: no Metal device
|
|
id<MTLComputePipelineState> pipeline = nil;
|
|
id<MTLCommandQueue> queue = nil;
|
|
};
|
|
|
|
// Compiled once per process, the first time it is asked for.
|
|
const Kernel &GetKernel() {
|
|
static const Kernel kernel = [] {
|
|
Kernel k;
|
|
k.device = MTLCreateSystemDefaultDevice();
|
|
if (k.device == nil)
|
|
return k;
|
|
MTLCompileOptions *options = [MTLCompileOptions new];
|
|
// Fast math off: nothing reassociated or approximated, as on the CPU.
|
|
options.fastMathEnabled = NO;
|
|
options.languageVersion = MTLLanguageVersion3_0;
|
|
NSError *error = nil;
|
|
id<MTLLibrary> library = [k.device newLibraryWithSource:@(side_chain_field_metal_source) options:options
|
|
error:&error];
|
|
if (library == nil)
|
|
throw JFJochException(JFJochExceptionCategory::GPUMetalError,
|
|
std::string("side-chain field kernel: ") + error.localizedDescription.UTF8String);
|
|
id<MTLFunction> function = [library newFunctionWithName:@"contribution"];
|
|
k.pipeline = [k.device newComputePipelineStateWithFunction:function error:&error];
|
|
if (k.pipeline == nil)
|
|
throw JFJochException(JFJochExceptionCategory::GPUMetalError,
|
|
std::string("contribution: ") + error.localizedDescription.UTF8String);
|
|
k.queue = [k.device newCommandQueue];
|
|
return k;
|
|
}();
|
|
return kernel;
|
|
}
|
|
|
|
id<MTLBuffer> NewBuffer(id<MTLDevice> device, size_t bytes) {
|
|
id<MTLBuffer> b = [device newBufferWithLength:std::max<size_t>(bytes, 4) options:MTLResourceStorageModeShared];
|
|
if (b == nil)
|
|
throw JFJochException(JFJochExceptionCategory::GPUMetalError, "side-chain field: out of GPU memory");
|
|
return b;
|
|
}
|
|
|
|
id<MTLBuffer> Upload(id<MTLDevice> device, const std::vector<float> &v) {
|
|
id<MTLBuffer> b = NewBuffer(device, v.size() * sizeof(float));
|
|
std::memcpy(b.contents, v.data(), v.size() * sizeof(float));
|
|
return b;
|
|
}
|
|
|
|
struct Params {
|
|
uint32_t rows, n_ops, first;
|
|
};
|
|
|
|
} // namespace
|
|
|
|
struct SideChainFieldMetal::Impl {
|
|
uint32_t rows, n_ops;
|
|
id<MTLBuffer> hx, hy, hz, ht, f0, stol2;
|
|
};
|
|
|
|
SideChainFieldMetal::SideChainFieldMetal(std::unique_ptr<Impl> impl) : impl_(std::move(impl)) {}
|
|
|
|
SideChainFieldMetal::~SideChainFieldMetal() = default;
|
|
|
|
std::unique_ptr<SideChainFieldMetal> SideChainFieldMetal::Make(size_t rows, size_t n_ops, const std::vector<float> &hx,
|
|
const std::vector<float> &hy,
|
|
const std::vector<float> &hz,
|
|
const std::vector<float> &ht,
|
|
const std::vector<float> &f0,
|
|
const std::vector<float> &stol2) {
|
|
@autoreleasepool {
|
|
if (gpus_are_hidden() || rows * std::max<size_t>(n_ops, 1) > std::numeric_limits<uint32_t>::max())
|
|
return nullptr;
|
|
const Kernel &k = GetKernel();
|
|
if (k.device == nil)
|
|
return nullptr;
|
|
auto impl = std::make_unique<Impl>();
|
|
impl->rows = static_cast<uint32_t>(rows);
|
|
impl->n_ops = static_cast<uint32_t>(n_ops);
|
|
impl->hx = Upload(k.device, hx);
|
|
impl->hy = Upload(k.device, hy);
|
|
impl->hz = Upload(k.device, hz);
|
|
impl->ht = Upload(k.device, ht);
|
|
impl->f0 = Upload(k.device, f0);
|
|
impl->stol2 = Upload(k.device, stol2);
|
|
return std::unique_ptr<SideChainFieldMetal>(new SideChainFieldMetal(std::move(impl)));
|
|
}
|
|
}
|
|
|
|
void SideChainFieldMetal::Contributions(const FieldStates &states, int first,
|
|
std::vector<std::vector<std::complex<float>>> &out) {
|
|
// In a pool of its own, as ModelDensityMetal(): the threads this runs on have none.
|
|
@autoreleasepool {
|
|
const Kernel &k = GetKernel();
|
|
const size_t rows = impl_->rows, count = out.size();
|
|
if (count == 0)
|
|
return;
|
|
id<MTLBuffer> d_atoms = NewBuffer(k.device, states.atoms.size() * sizeof(FieldAtom));
|
|
std::memcpy(d_atoms.contents, states.atoms.data(), states.atoms.size() * sizeof(FieldAtom));
|
|
id<MTLBuffer> d_start = NewBuffer(k.device, states.start.size() * sizeof(int));
|
|
std::memcpy(d_start.contents, states.start.data(), states.start.size() * sizeof(int));
|
|
id<MTLBuffer> d_out = NewBuffer(k.device, count * rows * sizeof(std::complex<float>));
|
|
const Params p{impl_->rows, impl_->n_ops, static_cast<uint32_t>(first)};
|
|
|
|
id<MTLCommandBuffer> cb = [k.queue commandBuffer];
|
|
id<MTLComputeCommandEncoder> e = [cb computeCommandEncoder];
|
|
[e setComputePipelineState:k.pipeline];
|
|
id<MTLBuffer> tables[] = {impl_->hx, impl_->hy, impl_->hz, impl_->ht, impl_->f0, impl_->stol2};
|
|
for (int i = 0; i < 6; i++)
|
|
[e setBuffer:tables[i] offset:0 atIndex:i];
|
|
[e setBuffer:d_atoms offset:0 atIndex:6];
|
|
[e setBuffer:d_start offset:0 atIndex:7];
|
|
[e setBytes:&p length:sizeof(p) atIndex:8];
|
|
[e setBuffer:d_out offset:0 atIndex:9];
|
|
[e dispatchThreads:MTLSizeMake(rows, count, 1) threadsPerThreadgroup:MTLSizeMake(256, 1, 1)];
|
|
[e endEncoding];
|
|
[cb commit];
|
|
[cb waitUntilCompleted];
|
|
if (cb.status != MTLCommandBufferStatusCompleted)
|
|
throw JFJochException(JFJochExceptionCategory::GPUMetalError,
|
|
cb.error ? cb.error.localizedDescription.UTF8String
|
|
: "side-chain field: command buffer failed");
|
|
const auto *f = static_cast<const std::complex<float> *>(d_out.contents);
|
|
for (size_t s = 0; s < count; s++)
|
|
out[s].assign(f + s * rows, f + (s + 1) * rows);
|
|
states_on_gpu += count;
|
|
}
|
|
}
|
|
|
|
size_t SideChainFieldMetal::States() {
|
|
return states_on_gpu;
|
|
}
|