include(ExternalProject)

find_package(ZLIB REQUIRED)

# libjpeg-turbo: upstream does NOT support add_subdirectory/FetchContent inclusion, so build and
# install it out-of-line and import the static lib. (Adapted from aseprite's FindJpegTurbo.cmake.)
# The static lib is `jpeg-static.lib` on MSVC and `libjpeg.a` elsewhere.
IF (MSVC)
    SET(LIBJPEG_TURBO_STATIC_SUFFIX "-static")
ELSE()
    SET(LIBJPEG_TURBO_STATIC_SUFFIX "")
ENDIF()
SET(LIBJPEG_TURBO_DIR "${CMAKE_CURRENT_BINARY_DIR}/libjpeg-turbo")
SET(LIBJPEG_TURBO_LIBRARY "${LIBJPEG_TURBO_DIR}/lib/${CMAKE_STATIC_LIBRARY_PREFIX}jpeg${LIBJPEG_TURBO_STATIC_SUFFIX}${CMAKE_STATIC_LIBRARY_SUFFIX}")
SET(LIBJPEG_TURBO_INCLUDE_DIRS "${LIBJPEG_TURBO_DIR}/include")

ExternalProject_Add(libjpeg-turbo-project
        GIT_REPOSITORY https://github.com/libjpeg-turbo/libjpeg-turbo
        GIT_TAG 3.0.4
        PREFIX "${LIBJPEG_TURBO_DIR}"
        INSTALL_DIR "${LIBJPEG_TURBO_DIR}"
        BUILD_BYPRODUCTS "${LIBJPEG_TURBO_LIBRARY}"
        CMAKE_CACHE_ARGS
        -DENABLE_SHARED:BOOL=OFF
        -DENABLE_STATIC:BOOL=ON
        -DWITH_ARITH_DEC:BOOL=ON
        -DWITH_ARITH_ENC:BOOL=ON
        -DWITH_JPEG8:BOOL=OFF
        -DWITH_JPEG7:BOOL=OFF
        -DWITH_TURBOJPEG:BOOL=OFF
        # Lazy SIMD: use NASM-accelerated SIMD when nasm is present, otherwise warn and build a
        # scalar libjpeg (REQUIRE_SIMD=OFF is libjpeg-turbo's default; pinned here to be explicit).
        -DWITH_SIMD:BOOL=ON
        -DREQUIRE_SIMD:BOOL=OFF
        -DCMAKE_BUILD_TYPE:STRING=${CMAKE_BUILD_TYPE}
        -DCMAKE_INSTALL_PREFIX:PATH=<INSTALL_DIR>
        -DCMAKE_INSTALL_LIBDIR:PATH=<INSTALL_DIR>/lib)

# Create the include dir up front so setting INTERFACE_INCLUDE_DIRECTORIES below does not fail.
FILE(MAKE_DIRECTORY ${LIBJPEG_TURBO_INCLUDE_DIRS})

ADD_LIBRARY(JPEG::JPEG STATIC IMPORTED GLOBAL)
SET_TARGET_PROPERTIES(JPEG::JPEG PROPERTIES
        IMPORTED_LOCATION "${LIBJPEG_TURBO_LIBRARY}"
        INTERFACE_INCLUDE_DIRECTORIES "${LIBJPEG_TURBO_INCLUDE_DIRS}")

ADD_LIBRARY(JFJochPreview STATIC
        JFJochTIFF.cpp JFJochTIFF.h
        JFJochJPEG.cpp JFJochJPEG.h
        PreviewCounter.cpp PreviewCounter.h
        PreviewImage.cpp PreviewImage.h
        ZMQPreviewSocket.cpp
        ZMQPreviewSocket.h
        ZMQMetadataSocket.cpp
        ZMQMetadataSocket.h
)

# JPEG::JPEG is an IMPORTED target, so the build-order dependency on the ExternalProject must be
# attached to the consuming target instead.
ADD_DEPENDENCIES(JFJochPreview libjpeg-turbo-project)

TARGET_LINK_LIBRARIES(JFJochPreview PUBLIC JFJochZMQ JFJochCommon CBORStream2FrameSerialize)
TARGET_LINK_LIBRARIES(JFJochPreview PUBLIC JPEG::JPEG tiff tiffxx ZLIB::ZLIB)

