NO TE: KOWARI - CONTROLLER 4
NO TE:
NO TE: $Revision: 1.2 $
NO TE: $Date: 2007/09/24 01:25:23 $
NO TE: Author: Dan Bartlett
NO TE: Last revision by: $Author: dbx $
NO TE:
NO TE: A-PRE SAMPLE COLLIMATOR X (ACROSS BEAM)
NO TE: B-PRE SAMPLE COLLIMATOR Y (ALONG BEAM)
NO TE: C-PRE SAMPLE COLLIMATOR WIDTH
NO TE: D-POST SAMPLE COLLIMATOR X (ACROSS BEAM)
NO TE: E-POST SAMPLE COLLIMATOR Y (ALONG BEAM)
NO TE: F-POST SAMPLE COLLIMATOR WIDTH
NO TE: G-SPARE AXIS CABLED FOR CRADLE
NO TE: H-SPARE
NO ----------------------------------------
#AUTO
NO TE: THIS IS THE PROGRAM THAT RUNS AUTOMATICALLY ON CONTROLLER STARTUP
MT-2,-2,-2,-2,-2,-2,-2,-2;'CONFIGURES ALL AXES AS STEPPER
MO;' FIRST TIME MOTOR OFF
CN 1;' CONFIGURES LIMIT SWITCHES TO ACCEPT NC CONTACTS
II 8,,,0;' CONFIGURES THE 8TH INPUT TO ACTIVATE THE #ININT ROUTINE
OP 65280;' SETS OUTPUTS 9-16 ON = RELAYS OFF
IA 137,157,201,198;' CONFIGURES IP ADDRESS
AC 25000,25000,25000,25000,25000,25000,25000,;' SET ACELERATION
DC 25000,25000,25000,25000,25000,25000,25000,;' SET DECELERATION
SP 25000,25000,25000,25000,25000,25000,25000,;' SET SPEED
SIA=1,25,13,0<-2>2;'HEIDENHAIN ROQ425
SIB=1,25,13,0<-2>2;'HEIDENHAIN ROQ425
SIC=1,25,13,0<-2>2;'HEIDENHAIN ROQ425
SID=1,25,13,0<-2>2;'HEIDENHAIN ROQ425
SIE=1,25,13,0<-2>2;'HEIDENHAIN ROQ425
SIF=1,25,13,0<-2>2;'HEIDENHAIN ROQ425
SIG=1,25,13,0<-2>2;'HEIDENHAIN ROQ425
SIH=0,25,13,0<-2>2;'NOT USED
hndIP=-1986147895;'STATIC IP ADDRESS OF THE WIRELESS HANDHELD TERMINAL 
CONNECT=0'VARIABLE TO TELL IF HANDHELD IS CONNECTED
EOMDEG=-1;' PART OF THE SAMPLE OSCILLATION CONTROL #OSCEOM
JS #THREAD0
EN
NO ----------------------------------------
#THREAD0
NO TE: THERE MUST BE A THREAD RUNNING FOR #LIMSWI, #TCPERR AND #ININT TO WORK
NO TE: CHECKS IF SPEEDS ARE ABOVE MAXIMUM ALLOWED
IF (_SPA>50000)
SPA=50000
ENDIF
IF (_SPB>50000)
SPB=50000
ENDIF
IF (_SPC>50000)
SPC=50000
ENDIF
IF (_SPD>50000)
SPD=50000
ENDIF
IF (_SPE>50000)
SPE=50000
ENDIF
IF (_SPF>50000)
SPF=50000
ENDIF
IF (_SPG>50000)
SPG=50000
ENDIF
NO IF (_SPH>50000)
NO SPH=50000
NO ENDIF
IF (_XQ1=-1);'THREAD2 NOT RUNNING
XQ #CHKHAND,1
ENDIF
IF (_XQ3=-1)&(EOMDEG<>-1);'THREAD3 NOT RUNNING & EOM OSC 
XQ #OSCEOM,3
ENDIF
JP #THREAD0
EN
NO ----------------------------------------
#TCPERR
'CLOSE TCP CONNECTION, STOP AND TURN OFF MOTORS
CONNECT=0
IHH=>-2
ST ABBCDEFG
MC ABBCDEFG
MO ABBCDEFG
RE
NO ----------------------------------------
#ININT
NO TE: INTERUPT ROUTINE TO STOP ALL AXES
NO TE: WHEN SAFETY & INTERLOCK SYSTEM REQUESTS IT
STA,B,C,D,E,F,G,H
AM
MO
RI
NO ----------------------------------------
#LIMSWI
NO TE: LIMIT SWITCH ROUTINE WHICH SHORTENS DECEL TIME WHEN A LIMIT IS HIT
OLDDCA=_DCA;' REMEMBERS CURRENT DECEL
OLDDCB=_DCB
OLDDCC=_DCC
OLDDCD=_DCD
OLDDCE=_DCE
OLDDCF=_DCF
OLDDCG=_DCG
NO OLDDCH=_DCH AXIS NOT USED
IF (_LFA = 0) | (_LRA = 0)
DCA=100000;' DECEL FOR LIMIT HIT OCCURENCE
STA
ENDIF
IF (_LFB = 0) | (_LRB = 0)
DCB=100000;' DECEL FOR LIMIT HIT OCCURENCE
STB
ENDIF
IF (_LFC = 0) | (_LRC = 0)
DCC=100000;' DECEL FOR LIMIT HIT OCCURENCE
STC
ENDIF
IF (_LFD = 0) | (_LRD = 0)
DCD=100000;' DECEL FOR LIMIT HIT OCCURENCE
STD
ENDIF
IF (_LFE = 0) | (_LRE = 0)
DCE=100000;' DECEL FOR LIMIT HIT OCCURENCE
STE
ENDIF
IF (_LFF = 0) | (_LRF = 0)
DCF=50000;' DECEL FOR LIMIT HIT OCCURENCE
STF
ENDIF
IF (_LFG = 0) | (_LRG = 0)
DCG=100000;' DECEL FOR LIMIT HIT OCCURENCE
STG
ENDIF
NO IF (_LFH = 0) | (_LRH = 0)
NO DCH=100000;' DECEL FOR LIMIT HIT OCCURENCE
NO STH
NO ENDIF
AM ABCDEFGH;' AFTER ALL AXES STOPPED
DCA=OLDDCA;' RESET DECEL TO OLD VALUE
DCB=OLDDCB
DCC=OLDDCC
DCD=OLDDCD
DCE=OLDDCE
DCF=OLDDCF
DCG=OLDDCG
NO DCH=OLDDCH AXIS NOT USED
RE
'-----------------------------------------------------------------------------
#CHKHAND
'IF THERE IS A TCP CONNECTION BETWEEN THE HANDHELD AND GALIL 
'ON HANDLE 'A' MOVE IT TO HANDLE H
'_IHn0=IP ADDRESS
'_IHn2=0 (NO CONNECTION)
'_IHn2=1 (UDP SLAVE)
'_IHn2=2 (TCP SLAVE)
IF((_IHA0=hndIP) & (_IHA2<>0))
HSA=H
ENDIF
'
IF((_IHB0=hndIP) & (_IHB2<>0)) 
HSB=H
ENDIF
'
IF((_IHC0=hndIP) & (_IHC2<>0)) 
HSC=H
ENDIF
'
IF((_IHD0=hndIP) & (_IHD2<>0))
HSD=H
ENDIF
'
IF((_IHE0=hndIP) & (_IHE2<>0))
HSE=H
ENDIF
'
IF((_IHF0=hndIP) & (_IHF2<>0))
HSF=H
ENDIF
'
IF((_IHG0=hndIP) & (_IHG2<>0))
HSG=H
ENDIF
'
'IF THERE IS A TCP CONNECTION BETWEEN THE HANDHELD AND GALIL 
'ON HANDLE 'H', SEND THE HEARTBEAT MESSAGE
IF((_IHH0=hndIP) & (_IHH2<>0))
MG "CONNECTED" {EH}
CONNECT=1
WT500
ENDIF
'
JP #CHKHAND
EN
'
'
'-----------------------------------------------------------------------
#OSCEOM
'THIS ROUTINE OSCILLATES THE SAMPLE
'ABOUT THE STARTING POINT +- 1/2 THE VALUE IN OSCDEG IN DEGREES
'
IF (EOMDEG<0.1)|(EOMDEG>200)
'OUTSIDE ALLOWABLE RANGE
EOMDEG=-1
JP #ENDOSC
ENDIF
'
DPG=0;' REMEMBER STARTING POSITION OF SAMPLE
SHG
PRG=25000*EOMDEG*0.5
'FIRST MOVE IS HALF THE TOTAL AND REMEMBER DISTANCE
BGG
MCG
WT500
#LPOSC
PRG=-25000*EOMDEG
BGG
MCG
WT500
PRG=25000*EOMDEG
BGG
MCG
WT500
JP #LPOSC,EOMDEG<>-1
'CONTINUE TO LOOP UNTIL OSCDEG IS SET TO -1
'
PAG=0;' RETURN SAMPLE TO STARTING POSITION
BGG
MCG
#ENDOSC
MOE
EN
'-----------------------------------------------------------------------