NO TE: TAIPAN - CONTROLLER 5
NO TE: 
NO TE: $Revision: 1.2 $
NO TE: $Date: 2007-09-24 01:29:31 $
NO TE: Author: Dan Bartlett
NO TE: Last revision by: $Author: dbx $
NO TE:
NO TE: A-SECONDARY SHUTTER, +VE OPEN, 6mm/TURN
NO TE: ONE AXIS CONTROLLER ONLY
NO ----------------------------------------
#AUTO
NO TE: THIS IS THE PROGRAM THAT RUNS AUTOMATICALLY ON CONTROLLER STARTUP
SHA
MTA=-2;'CONFIGURES ALL AXES AS STEPPER
CN 1;' CONFIGURES LIMIT SWITCHES TO ACCEPT NC CONTACTS
IA 137,157,203,135;' CONFIGURES IP ADDRESS
ACA=100000;' SET ACELERATION
DCA=100000;' SET DECELERATION
SPA=50000;' SET SPEED
JS #THREAD0
EN
NO ----------------------------------------
#THREAD0
NO TE: CONTROLS THE SECONDARY SHUTTER
NO TE: INPUT 5=SECONDARY SHUTTER CLOSE SIGNAL 1
NO TE: INPUT 6=SECONDARY SHUTTER CLOSE SIGNAL 2
NO TE: INPUT 7=SECONDARY SHUTTER OPEN SIGNAL 1
NO TE: INPUT 8=SECONDARY SHUTTER OPEN SIGNAL 2
IF ((_TI0&192)=0)&(_BGA=0)&(_LFA=1)
NO TE: INPUTS 7,8 EXCLUSIVELY ACTIVE(0) & NOT MOVING & NOT ALREADY OPEN
NO TE: SECONDARY SHUTTER COMMANDED TO OPEN
NO TE: INPUTS 1,2,3 AND 4 ARE MASKED OUT BY THE &192
PRA=580000;'APROX 140mm
BGA
ENDIF
IF ((_TI0&192<>0)&(_LRA=1)
NO TE: INPUTS 7,8 NOT EXCLUSIVELY ACTIVE(0) & NOT ALREADY CLOSED
NO TE: SECONDARY SHUTTER COMMANDED TO CLOSE
NO TE: INPUTS 1,2,3 AND 4 ARE MASKED OUT BY THE &192
STA;' STOP ANY MOTION
AMA;' AFTER MOTION IS STOPPED
PRA=-580000;' APROX 140mm
BGA;' DRIVE SHUTTER CLOSED TO LIMIT SWITCH
AMA
ENDIF
JP #THREAD0
EN
NO ----------------------------------------
#TCPERR
NO TE: EMPTY ROUTINE FOR A TCP ERROR
RE
NO ----------------------------------------
#CMDERR
NO TE: THIS IS A ROUTINE TO HANDLE COMMAND ERRORS
ZS0;' ZERO STACK
EN1
NO ----------------------------------------
#MONSWI
NO TE: THIS IS A ROUTINE TO MONITOR THE POSITION
NO TE: OF THE SECONDARY SHUTTER
IF (_LFA=1)&(_LRA=1)
MG {EA}, "SS NOT OPEN, NOT CLOSED"
WT200
ENDIF
JP #MONSWI
EN
NO ----------------------------------------