NO TE: QUOKKA - CONTROLLER 1
NO TE:
NO TE: $Revision: 1.4 $
NO TE: $Date: 2007-05-31 06:33:10 $
NO TE: Author: Dan Bartlett
NO TE: Last revision by: $Author: dbx $
NO TE:
NO TE: A-SAMPLE UPPER TILT
NO TE: B-SAMPLE LOWER TILT
NO TE: C-SAMPLE TRANSLATION Y (ACROSS BEAM)
NO TE: D-SAMPLE TRANSLATION X (ALONG BEAM)
NO TE: E-SAMPLE RAISE
NO TE: F-SAMPLE ROTATE
NO TE: G-DETECTOR Y (ALONG BEAM)
NO TE: H-DETECTOR X (ACCROSS BEAM)
NO ----------------------------------------
#AUTO
NO TE: THIS IS THE PROGRAM THAT RUNS AUTOMATICALLY ON CONTROLLER STARTUP
MT-2,-2,-2,-2,-2,-2,-2,-2;'CONFIGURES ALL AXES AS STEPPER
MO;' FIRST TIME MOTOR OFF
CN 1;' CONFIGURES LIMIT SWITCHES TO ACCEPT NC CONTACTS
II 8,,,0;' CONFIGURES THE 8TH INPUT TO ACTIVATE THE #ININT ROUTINE
OP 65280;' SETS OUTPUTS 9-16 ON = RELAYS OFF
IA 137,157,202,69;' CONFIGURES IP ADDRESS
AC 25000,25000,25000,25000,25000,25000,25000,25000;' SET ACELERATION
DC 25000,25000,25000,25000,25000,25000,25000,25000;' SET DECELERATION
SP 25000,25000,25000,50000,25000,25000,25000,25000;' SET SPEED
SIA=1,25,13,0<-2>2;'HEIDENHAIN ROQ425
SIB=1,25,13,0<-2>2;'HEIDENHAIN ROQ425
SIC=1,25,13,0<-2>2;'HEIDENHAIN ROQ425
SID=1,25,13,0<-2>2;'HEIDENHAIN ROQ425
SIE=1,25,13,0<-2>2;'HEIDENHAIN ROQ425
SIF=1,25,13,0<-2>2;'HEIDENHAIN ROQ425
SIG=1,25,13,0<-2>2;'HEIDENHAIN ROQ425
SIH=1,25,13,0<-2>2;'HEIDENHAIN ROQ425
JS #THREAD0
EN
NO ----------------------------------------
#THREAD0
NO TE: THERE MUST BE A THREAD RUNNING FOR #LIMSWI, #TCPERR AND #ININT TO WORK
NO TE: CHECKS IF SPEEDS ARE ABOVE MAXIMUM ALLOWED
IF (_SPA>50000)
SPA=50000
ENDIF
IF (_SPB>50000)
SPB=50000
ENDIF
IF (_SPC>50000)
SPC=50000
ENDIF
IF (_SPD>100000)
SPD=100000
ENDIF
IF (_SPE>50000)
SPE=50000
ENDIF
IF (_SPF>50000)
SPF=50000
ENDIF
IF (_SPG>50000)
SPG=50000
ENDIF
IF (_SPH>50000)
SPH=50000
ENDIF
NO TE: CONTROLS THE SAMPLE RAISE ELECTRO-MECHANICAL BRAKE
IF (_MOE=0)
CB 13;' MOTOR ON = BRAKE ENERGISED = UNLOCKED
ELSE
SB 13;' MOTOR OFF = BRAKE DENERGISED = LOCKED
ENDIF
JP #THREAD0
EN
NO ----------------------------------------
#TCPERR
NO TE: EMPTY ROUTINE FOR A TCP ERROR
RE
NO ----------------------------------------
#ININT
NO TE: INTERUPT ROUTINE TO STOP ALL AXES
NO TE: WHEN SAFETY & INTERLOCK SYSTEM REQUESTS IT
STA,B,C,D,E,F,G,H
AM
MO
RI
NO ----------------------------------------
#LIMSWI
NO TE: LIMIT SWITCH ROUTINE WHICH SHORTENS DECEL TIME WHEN A LIMIT IS HIT
OLDDCA=_DCA;' REMEMBERS CURRENT DECEL
OLDDCB=_DCB
OLDDCC=_DCC
OLDDCD=_DCD
OLDDCE=_DCE
OLDDCF=_DCF
OLDDCG=_DCG
OLDDCH=_DCH
IF (_LFA = 0) | (_LRA = 0)
DCA=100000;' DECEL FOR LIMIT HIT OCCURENCE
STA
ENDIF
IF (_LFB = 0) | (_LRB = 0)
DCB=100000;' DECEL FOR LIMIT HIT OCCURENCE
STB
ENDIF
IF (_LFC = 0) | (_LRC = 0)
DCC=100000;' DECEL FOR LIMIT HIT OCCURENCE
STC
ENDIF
IF (_LFD = 0) | (_LRD = 0)
DCD=100000;' DECEL FOR LIMIT HIT OCCURENCE
STD
ENDIF
IF (_LFE = 0) | (_LRE = 0)
DCE=100000;' DECEL FOR LIMIT HIT OCCURENCE
STE
ENDIF
IF (_LFF = 0) | (_LRF = 0)
DCF=100000;' DECEL FOR LIMIT HIT OCCURENCE
STF
ENDIF
IF (_LFG = 0) | (_LRG = 0)
DCG=100000;' DECEL FOR LIMIT HIT OCCURENCE
STG
ENDIF
IF (_LFH = 0) | (_LRH = 0)
DCH=100000;' DECEL FOR LIMIT HIT OCCURENCE
STH
ENDIF
AM ABCDEFGH;' AFTER ALL AXES STOPPED
DCA=OLDDCA;' RESET DECEL TO OLD VALUE
DCB=OLDDCB
DCC=OLDDCC
DCD=OLDDCD
DCE=OLDDCE
DCF=OLDDCF
DCG=OLDDCG
DCH=OLDDCH
RE