'TAIPAN - CONTROLLER 5
' 
'$Revision:$
'$Date$
'Author: Dan Bartlett
'Last revision by: $Author:$
'
'A-SECONDARY SHUTTER, +VE OPEN, 6mm/TURN
'ONE AXIS CONTROLLER ONLY
'
'
'-----------------------------------------------------------------------------
#AUTO
NO TE: THIS IS THE PROGRAM THAT RUNS AUTOMATICALLY ON CONTROLLER STARTUP
'
MO;'MOTOR OFF
SIA=1,24,12,0<-2>1;'RESOLVER VIA VEGA 2790 BOARD
MTA=-2;'CONFIGURES AXIS AS STEPPER
CN 1;' CONFIGURES LIMIT SWITCH TO ACCEPT NC CONTACTS
IA 137,157,203,135;' CONFIGURES IP ADDRESS
ACA=100000;' SET ACELERATION
DCA=100000;' SET DECELERATION
SPA=50000;' SET SPEED
JS #THREAD0
EN
'
'
'-----------------------------------------------------------------------------
#THREAD0
'CONTROLS THE SECONDARY SHUTTER
'
'INPUT 5=SECONDARY SHUTTER CLOSE SIGNAL 1
'INPUT 6=SECONDARY SHUTTER CLOSE SIGNAL 2
'INPUT 7=SECONDARY SHUTTER OPEN SIGNAL 1
'INPUT 8=SECONDARY SHUTTER OPEN SIGNAL 2
IF ((@IN[5]=1)&(@IN[6]=1)&(@IN[7]=0)&(@IN[8]=0)&(_BGA=0)&(_LFA=1))
'INPUTS 5&6 INACTIVE(1) & INPUT 7&8 ACTIVE(0) & NOT MOVING & NOT ALREADY OPEN
'SECONDARY SHUTTER COMMANDED TO OPEN
JGA=50000;' JOG OPEN AT 12mm/s
SHA;' TURN ON MOTOR
BGA;' DRIVE SHUTTER OPEN
ENDIF
IF (((@IN[7]=1)|(@IN[8]=1))&(_LRA=1))
'EITHER OF INPUTS 7 OR 8 INACTIVE(1) & NOT ALREADY CLOSED
'SECONDARY SHUTTER COMMANDED TO CLOSE
STA;' STOP ANY MOTION
MCA;' AFTER MOTION IS STOPPED
JGA=-50000;' JOG CLOSED AT 12mm/s
SHA;' TURN ON MOTOR
BGA;' DRIVE SHUTTER CLOSED
MCA
ENDIF
IF (((_LFA=0)|(_LRA=0))&(_BGA=0))
'AT EITHER LIMIT AND NOT MOVING
MOA;' TURN OFF MOTOR
ENDIF
JP #THREAD0
EN
'
'
'-----------------------------------------------------------------------------
#TCPERR
'EMPTY TCP ERROR ROUTINE
'
RE
'
'
'-----------------------------------------------------------------------------
#CMDERR
'ROUTINE TO HANDLE COMMAND ERRORS
'
ZS0
EN1
'
'