NO TE: QUOKKA - CONTROLLER 3
NO TE:
NO TE: $Revision: 1.6 $
NO TE: $Name: not supported by cvs2svn $
NO TE: $Date: 2008-05-30 00:26:57 $
NO TE: Author: Dan Bartlett
NO TE: Last revision by: $Author: ffr $
NO TE:
NO TE: A-COLLIMATION OPTICS - CHAMBER 9
NO TE: B-COLLIMATION OPTICS - CHAMBER 10
NO TE: C-SOURCE END CHAMBER - PENTAPRISM
NO TE: D-SOURCE END CHAMBER - SRC APERTURES
NO TE: E-SPARE WITH 8 AMP AMPLIFIER
NO TE: F-SPARE WITH 8 AMP AMPLIFIER
NO TE: G-ROTARY ATTENUATOR
NO TE: H-SPARE
NO TE:
NO TE: +VE MOTOR MOVES COLL. 9&10 IN A WESTERLY DIRECTION
NO ----------------------------------------
#AUTO
NO TE: THIS IS THE PROGRAM THAT RUNS AUTOMATICALLY ON CONTROLLER STARTUP
MT-2,-2,-2,-2,-2,-2,-2,-2;'CONFIGURES ALL AXES AS STEPPER
MO;' FIRST TIME MOTOR OFF
CN 1;' CONFIGURES LIMIT SWITCHES TO ACCEPT NC CONTACTS
II 8,,,0;' CONFIGURES THE 8TH INPUT TO ACTIVATE THE #ININT ROUTINE
OP 65280;' SETS OUTPUTS 9-16 ON = RELAYS OFF
IA 137,157,202,69;' CONFIGURES IP ADDRESS
AC 12500,12500,25000,25000,,,25000,;' SET ACELERATION
DC 12500,12500,25000,25000,,,25000,;' SET DECELERATION
SP 25000,25000,25000,25000,,,25000,;' SET SPEED
SIA=1,25,13,0<-2>2;'HEIDENHAIN ROQ425
SIB=1,25,13,0<-2>2;'HEIDENHAIN ROQ425
SIC=1,25,13,0<-2>2;'HEIDENHAIN ROQ425
SID=1,25,13,0<-2>2;'HEIDENHAIN ROQ425
SIE=0,25,13,0<-2>2;'NOT USED
SIF=0,25,13,0<-2>2;'NOT USED
SIG=1,25,13,0<-2>2;'HEIDENHAIN ROQ425
SIH=0,25,13,0<-2>2;'NOT USED
JS #THREAD0
EN
NO ----------------------------------------
#THREAD0
NO TE: THERE MUST BE A THREAD RUNNING FOR #LIMSWI, #TCPERR AND #ININT TO WORK
NO TE: CHECKS IF SPEEDS ARE ABOVE MAXIMUM ALLOWED
IF (_SPA>25000)
SPA=25000
ENDIF
IF (_SPB>25000)
SPB=25000
ENDIF
IF (_SPC>50000)
SPC=50000
ENDIF
IF (_SPD>50000)
SPD=50000
ENDIF
NO IF (_SPE>50000)
NO SPE=50000
NO ENDIF
NO IF (_SPF>50000)
NO SPF=50000
NO ENDIF
IF (_SPG>50000)
SPG=50000
ENDIF
NO IF (_SPH>50000)
NO SPH=50000
NO ENDIF
JP #THREAD0
EN
NO ----------------------------------------
#TCPERR
NO TE: EMPTY ROUTINE FOR A TCP ERROR
RE
NO ----------------------------------------
#ININT
NO TE: INTERUPT ROUTINE TO STOP ALL AXES
NO TE: WHEN SAFETY & INTERLOCK SYSTEM REQUESTS IT
STA,B,C,D,E,F,G,H
AM
MO
RI
NO ----------------------------------------
#CMDERR
NO TE: THIS IS A ROUTINE TO HANDLE COMMAND ERRORS
ZS0;' ZERO STACK
EN1
NO ----------------------------------------
#LIMSWI
NO TE: LIMIT SWITCH ROUTINE WHICH SHORTENS DECEL TIME WHEN A LIMIT IS HIT
OLDDCA=_DCA;' REMEMBERS CURRENT DECEL
OLDDCB=_DCB
OLDDCC=_DCC
OLDDCD=_DCD
NO OLDDCE=_DCE
NO OLDDCF=_DCF
OLDDCG=_DCG
NO OLDDCH=_DCH
IF (_LFA = 0) | (_LRA = 0)
DCA=75000;' DECEL FOR LIMIT HIT OCCURENCE
STA
ENDIF
IF (_LFB = 0) | (_LRB = 0)
DCB=75000;' DECEL FOR LIMIT HIT OCCURENCE
STB
ENDIF
IF (_LFC = 0) | (_LRC = 0)
DCC=100000;' DECEL FOR LIMIT HIT OCCURENCE
STC
ENDIF
IF (_LFD = 0) | (_LRD = 0)
DCD=100000;' DECEL FOR LIMIT HIT OCCURENCE
STD
ENDIF
NO IF (_LFE = 0) | (_LRE = 0)
NO DCE=100000;' DECEL FOR LIMIT HIT OCCURENCE
NO STE
NO ENDIF
NO IF (_LFF = 0) | (_LRF = 0)
NO DCF=100000;' DECEL FOR LIMIT HIT OCCURENCE
NO STF
NO ENDIF
IF (_LFG = 0) | (_LRG = 0)
DCG=100000;' DECEL FOR LIMIT HIT OCCURENCE
STG
ENDIF
NO IF (_LFH = 0) | (_LRH = 0)
NO DCH=100000;' DECEL FOR LIMIT HIT OCCURENCE
NO STH
ENDIF
AM ABCDEFGH;' AFTER ALL AXES STOPPED
DCA=OLDDCA;' RESET DECEL TO OLD VALUE
DCB=OLDDCB
DCC=OLDDCC
DCD=OLDDCD
NO DCE=OLDDCE
NO DCF=OLDDCF
DCG=OLDDCG
NO DCH=OLDDCH
RE