#AUTO
NO TE: A-MONOCHROMATOR UPPER TILT (mphi) - TILT 1
NO TE: B-MONOCHROMATOR LOWER TILT (mchi) - TILT 2
NO TE: C-MONOCHROMATOR UPPER TRANSLATION (mz:nexus, mx:KDL) - LINEAR 1
NO TE: D-MONOCHROMATOR LOWER TRANSLATION (mx:nexus, my:KDL) - LINEAR 2
NO TE: E-MONOCHROMATOR ROTATION (mom) - ROTATE
NO TE: F-FLIGHT TUBE ROTATE
NO TE: G-PRIMARY COLLIMATOR 1
NO TE: H-PRIMARY COLLIMATOR 2
MT-2,-2,-2,-2,-2,-2,-2,-2
MO
CN 1
OP 65280
IA 137,157,201,66
AC 25000,25000,25000,25000,25000,10000,25000,25000
DC 25000,25000,25000,25000,25000,10000,25000,25000
SP 25000,25000,25000,25000,50000,100000,25000,25000
SIA=1,25,13,0<-1>2
SIB=1,25,13,0<-1>2
SIC=1,25,13,0<-1>2
SID=1,25,13,0<-1>2
SIE=1,25,13,0<-1>2
SIF=1,25,25,0<-1>2
SIG=1,25,13,0<-1>2
SIH=1,25,13,0<-1>2
DONE=0
JS #SOLCTRL
EN
#SOLCTRL
IF (_MOF=0);'FLIGHT TUBE MOTOR IS ON
SB 10;'SAMPLE STAGE AIR PAD OFF-SOLENOID OFF
SB 12;'DRIVE WHEEL UP-SOLENOID OFF
CB 9;'SAMPLE STAGE AIR PAD ON-SOLENOID ON
CB 11;'DRIVE WHEEL DOWN-SOLENOID ON
DONE=0
ENDIF
IF (_MOF=1)&(DONE=0);'FLIGHT TUBE MOTOR IS OFF
SB 9;'SAMPLE STAGE AIR PAD ON-SOLENOID OFF
SB 11;'DRIVE WHEEL DOWN-SOLENOID OFF
CB 10;'SAMPLE STAGE AIR PAD OFF-SOLENOID ON
CB 12;'DRIVE WHEEL UP-SOLENOID ON
WT500;'WAIT 1/2 SEC
SB 10;'SAMPLE STAGE AIR PAD OFF-SOLENOID OFF
SB 12;'DRIVE WHEEL UP-SOLENOID OFF
DONE=1
ENDIF
JP #SOLCTRL
EN
#TCPERR
RE
#LIMSWI
OLDDCA=_DCA
OLDDCB=_DCB
OLDDCC=_DCC
OLDDCD=_DCD
OLDDCE=_DCE
OLDDCF=_DCF
OLDDCG=_DCG
OLDDCH=_DCH
IF (_LFA = 0) | (_LRA = 0)
DCA=100000
STA
AMA
MOA
DCA=OLDDCA
ENDIF
IF (_LFB = 0) | (_LRB = 0)
DCB=100000
STB
AMB
MOB
DCB=OLDDCB
ENDIF
IF (_LFC = 0) | (_LRC = 0)
DCC=100000
STC
AMC
MOC
DCC=OLDDCC
ENDIF
IF (_LFD = 0) | (_LRD = 0)
DCD=100000
STD
AMD
MOD
DCD=OLDDCD
ENDIF
IF (_LFE = 0) | (_LRE = 0)
DCE=100000
STE
AME
MOE
DCE=OLDDCE
ENDIF
IF (_LFF = 0) | (_LRF = 0)
DCF=100000
STF
AMF
MOF
DCF=OLDDCF
ENDIF
IF (_LFG = 0) | (_LRG = 0)
DCG=100000
STG
AMG
MOG
DCG=OLDDCG
ENDIF
IF (_LFH = 0) | (_LRH = 0)
DCH=100000
STH
AMH
MOH
DCH=OLDDCH
ENDIF
RE