NO TE: PLAYTPUS - CONTROLLER 4
NO TE:
NO TE: $Revision: 1.2 $
NO TE: $Date: 2007-01-31 06:44:50 $
NO TE: Author: Dan Bartlett
NO TE: Last revision by: $Author: dbx $
NO TE:
NO TE: A-SLIT S3 TOP BLADE
NO TE: B-SLIT S3 BOTTOM BLADE
NO TE: C-SLIT S3 WEST BLADE
NO TE: D-SLIT S3 EAST BLADE
NO TE: E-SLIT S4 TOP BLADE
NO TE: F-SLIT S4 BOTTOM BLADE
NO TE: G-SLIT S4 WEST BLADE
NO TE: H-SLIT S4 EAST BLADE
NO ----------------------------------------
#AUTO
NO TE: THIS IS THE PROGRAM THAT RUNS AUTOMATICALLY ON CONTROLLER STARTUP
MT-2,-2,-2,-2,-2,-2,-2,-2;'CONFIGURES ALL AXES AS STEPPER
MO;' FIRST TIME MOTOR OFF
CN 1;' CONFIGURES LIMIT SWITCHES TO ACCEPT NC CONTACTS
II 8,,,0;' CONFIGURES THE 8TH INPUT TO ACTIVATE THE #ININT ROUTINE
IA 137,157,202,134;' CONFIGURES IP ADDRESS
AC 60000,60000,60000,60000,60000,60000,60000,60000;' SET ACELERATION
DC 60000,60000,60000,60000,60000,60000,60000,60000;' SET DECELERATION
SP 30000,30000,30000,30000,30000,30000,30000,30000;' SET SPEED
HOMERUN=0;' HOMING PROCEDURE HAS NOT BEEN RUN
JS #THREAD0
EN
NO ----------------------------------------
#THREAD0
NO TE: THERE MUST BE A THREAD RUNNING FOR #LIMSWI, #TCPERR AND #ININT TO WORK
NO TE: CHECKS IF SPEEDS ARE ABOVE MAXIMUM ALLOWED
IF (_SPA>30000)
SPA=30000
ENDIF
IF (_SPB>30000)
SPB=30000
ENDIF
IF (_SPC>30000)
SPC=30000
ENDIF
IF (_SPD>30000)
SPD=30000
ENDIF
IF (_SPE>30000)
SPE=30000
ENDIF
IF (_SPF>30000)
SPF=30000
ENDIF
IF (_SPG>30000)
SPG=30000
ENDIF
IF (_SPH>30000)
SPH=30000
ENDIF
JP#THREAD0
EN
NO ----------------------------------------
#TCPERR
NO TE: EMPTY ROUTINE FOR A TCP ERROR
RE
NO ----------------------------------------
#ININT
NO TE: INTERUPT ROUTINE TO STOP ALL AXES
NO TE: WHEN SAFETY & INTERLOCK SYSTEM REQUESTS IT
STA,B,C,D,E,F,G,H
AM
MO
RI
NO ----------------------------------------
#HOME
NO TE: THIS ROUTINE HOMES THE SLITS.
NO TE: IT USES THE HIGH REPEATABILITY HOME LIMIT SWITCH ON THE PLATYPUS SLITS
NO TE: IT WILL NOT WORK WITH OTHER SLIT PACKAGES WITHOUT THE HOME LIMITS
IF (HOMERUN = 1)
JP #ENDHOME
ENDIF
JG -30000,-30000,-30000,-30000,-30000,-30000,-30000,-30000
BG;' OPEN SLITS TO LIMITS
AM ABCDEFGH
FE;' DRIVE TO THE HOME LIMIT AT FULL SPEED
BG
AM ABCDEFGH
PR -100625,-100625,-100625,-100625,-100625,-100625,-100625,-100625;' MOVE AWAY 5MM
BG
AM ABCDEFGH
SP 7500,7500,7500,7500,7500,7500,7500,7500;' REDUCE SPEED
FE;' DRIVE TO HOME LIMIT AT LOW SPEED
BG
AM ABCDEFGH
DP 0,0,0,0,0,0,0,0;' DEFINE EACH AXIS POSTION AS ZERO
HOMERUN=1;'HOMING PROCEDURE HAS BEEN RUN
#ENDHOME
EN