NO TE: PLATYPUS - CONTROLLER 2
NO TE:
NO TE: $Revision: 1.4 $
NO TE: $Date: 2008-02-03 23:41:32 $
NO TE: Author: Dan Bartlett
NO TE: Last revision by: $Author: dcl $
NO TE:
NO TE: A-SAMPLE TILT 1
NO TE: B-SAMPLE TILT 2
NO TE: C-SAMPLE TRANSLATION - LINEAR
NO TE: D-ANALYSER 1
NO TE: E-SAMPLE RAISE
NO TE: F-ANALYSER 2
NO TE: G-DETECTOR RAISE
NO TE: H-SPARE
NO ----------------------------------------
#AUTO
NO TE: THIS IS THE PROGRAM THAT RUNS AUTOMATICALLY ON CONTROLLER STARTUP
MT-2,-2,-2,-2,-2,-2,-2,-2;'CONFIGURES ALL AXES AS STEPPER
MO;' FIRST TIME MOTOR OFF
CN 1;' CONFIGURES LIMIT SWITCHES TO ACCEPT NC CONTACTS
II 8,,,0;' CONFIGURES THE 8TH INPUT TO ACTIVATE THE #ININT ROUTINE
OP 65280;' SETS OUTPUTS 9-16 ON = RELAYS OFF
IA 137,157,202,132;' CONFIGURES IP ADDRESS
AC 25000,25000,25000,25000,100000,25000,50000,;' SET ACELERATION
DC 25000,25000,25000,25000,100000,25000,50000,;' SET DECELERATION
SP 50000,50000,50000,25000,200000,25000,150000,;' SET SPEED
SIA=1,25,13,0<-2>2;'HEIDENHAIN ROQ425
SIB=1,25,13,0<-2>2;'HEIDENHAIN ROQ425
SIC=1,25,13,0<-2>2;'HEIDENHAIN ROQ425
SID=0,25,13,0<-2>2;'HEIDENHAIN ROQ425
SIE=1,25,13,0<-2>2;'HEIDENHAIN ROQ425
SIF=0,25,13,0<-2>2;'HEIDENHAIN ROQ425
SIG=1,25,13,0<-2>2;'HEIDENHAIN ROQ425
SIH=0,25,13,0<-2>2;'SPARE
NO TE: FIRST TIME THROUGH BRAKE CONTROL NOT DONE
REQG=0
RSPG=0
JS #THREAD0
EN
NO ----------------------------------------
#THREAD0
NO TE: THERE MUST BE A THREAD RUNNING FOR #LIMSWI, #TCPERR AND #ININT TO WORK
NO TE: CHECKS IF SPEEDS ARE ABOVE MAXIMUM ALLOWED
IF (_SPA>50000)
SPA=50000
ENDIF
IF (_SPB>50000)
SPB=50000
ENDIF
IF (_SPC>50000)
SPC=50000
ENDIF
IF (_SPD>50000)
SPD=50000
ENDIF
IF (_SPE>200000)
SPE=200000
ENDIF
IF (_SPF>100000)
SPF=100000
ENDIF
IF (_SPG>150000)
SPG=150000
ENDIF
NO IF (_SPH>50000) AXIS NOT USED, COMMENTED OUT
NO SPH=50000
NO ENDIF
NO TE: TO CONTROL THE BRAKE ON DETECTOR RAISE AXIS
IF (_MOG=0)&(RSPG=0);'DETECTOR RAISE MOTOR IS ON
REQG=1
ENDIF
IF (_MOG=1)&(RSPG=1);'DETECTOR RAISE MOTOR IS ON
REQG=0
ENDIF
IF (REQG=1)&(RSPG=0);'DETECTOR RAISE MOTOR IS REQUIRED
SHG
WT 200
CB 15;'RELAY ON = BRAKE COIL ENERGISED = BRAKE DISENGAGED
WT 300
RSPG=1
ENDIF
IF (REQG=0)&(RSPG=1);'DETECTOR RAISE MOTOR IS NOT REQUIRED
SB 15;'RELAY OFF = BRAKE COIL DE-ENERGISED = BRAKE ENGAGED
WT 400
MOG
WT 100
RSPG=0
ENDIF
JP #THREAD0
EN
NO ----------------------------------------
#TCPERR
NO TE: EMPTY ROUTINE FOR A TCP ERROR
RE
NO ----------------------------------------
#ININT
NO TE: INTERUPT ROUTINE TO STOP ALL AXES
NO TE: WHEN SAFETY & INTERLOCK SYSTEM REQUESTS IT
STA,B,C,D,E,F,G,H
AM
MO
RI
NO ----------------------------------------
#LIMSWI
NO TE: LIMIT SWITCH ROUTINE WHICH SHORTENS DECEL TIME WHEN A LIMIT IS HIT
OLDDCA=_DCA;' REMEMBERS CURRENT DECEL
OLDDCB=_DCB
OLDDCC=_DCC
OLDDCD=_DCD AXIS NOT USED
OLDDCE=_DCE
OLDDCF=_DCF AXIS NOT USED
OLDDCG=_DCG
NO OLDDCH=_DCH AXIS NOT USED
IF (_LFA = 0) | (_LRA = 0)
DCA=100000;' DECEL FOR LIMIT HIT OCCURENCE
STA
ENDIF
IF (_LFB = 0) | (_LRB = 0)
DCB=100000;' DECEL FOR LIMIT HIT OCCURENCE
STB
ENDIF
IF (_LFC = 0) | (_LRC = 0)
DCC=100000;' DECEL FOR LIMIT HIT OCCURENCE
STC
ENDIF
IF (_LFD = 0) | (_LRD = 0)
DCD=100000;' DECEL FOR LIMIT HIT OCCURENCE
STD
ENDIF
IF (_LFE = 0) | (_LRE = 0)
DCE=150000;' DECEL FOR LIMIT HIT OCCURENCE
STE
ENDIF
IF (_LFF = 0) | (_LRF = 0)
DCF=150000;' DECEL FOR LIMIT HIT OCCURENCE
STF
ENDIF
IF (_LFG = 0) | (_LRG = 0)
DCG=100000;' DECEL FOR LIMIT HIT OCCURENCE
STG
ENDIF
NO IF (_LFH = 0) | (_LRH = 0) AXIS NOT USED, COMMENTED OUT
NO DCH=100000;' DECEL FOR LIMIT HIT OCCURENCE
NO STH
NO ENDIF
AM ABCDEFGH;' AFTER ALL AXES STOPPED
DCA=OLDDCA;' RESET DECEL TO OLD VALUE
DCB=OLDDCB
DCC=OLDDCC
DCD=OLDDCD
DCE=OLDDCE
DCF=OLDDCF
DCG=OLDDCG
NO DCH=OLDDCH AXIS NOT USED
RE