NO TE: PLATYPUS - CONTROLLER 1
NO TE:
NO TE: $Revision: 1.10 $
NO TE: $Date: 2008-02-03 23:41:32 $
NO TE: Author: Dan Bartlett
NO TE: Last revision by: $Author: dcl $
NO TE:
NO TE: A-BEAM SHADE RAISE
NO TE: B-COLLIMATOR TRANSLATE A=7350364, B=6529772, C=6941582
NO TE: C-COLLIMATOR TILT, LEVEL=134660
NO TE: D-BEAM ATTENUATOR, BEAM CENTRE=8375078
NO TE: E-SLIT TOWER S3 RAISE
NO TE: F-SLIT TOWER S4 RAISE
NO TE: G-DETECTOR TRANSLATION Y (ALONG BEAM)
NO TE: H-SPARE
NO ----------------------------------------
#AUTO
NO TE: THIS IS THE PROGRAM THAT RUNS AUTOMATICALLY ON CONTROLLER STARTUP
MT-2,-2,-2,-2,-2,-2,-2,-2;'CONFIGURES ALL AXES AS STEPPER
MO;' FIRST TIME MOTOR OFF
CN 1;' CONFIGURES LIMIT SWITCHES TO ACCEPT NC CONTACTS
II 8,,,0;' CONFIGURES THE 8TH INPUT TO ACTIVATE THE #ININT ROUTINE
OP 65280;' SETS OUTPUTS 9-16 ON = RELAYS OFF
IA 137,157,202,131;' CONFIGURES IP ADDRESS
AC 25000,25000,25000,25000,25000,25000,12500,;' SET ACELERATION
DC 25000,25000,25000,25000,25000,25000,12500,;' SET DECELERATION
SP 50000,25000,25000,25000,75000,75000,12500,;' SET SPEED
SIA=1,25,13,0<-2>2;'HEIDENHAIN ROQ425
SIB=1,25,13,0<-2>2;'HEIDENHAIN ROQ425
SIC=1,24,18,6<-2>2;'IVO
SID=1,25,13,0<-2>2;'HEIDENHAIN ROQ425
SIE=1,25,13,0<-2>2;'HEIDENHAIN ROQ425
SIF=1,25,13,0<-2>2;'HEIDENHAIN ROQ425
SIG=1,25,13,0<-2>2;'HEIDENHAIN ROQ425
SIH=0,25,13,0<-2>2;'SPARE
NO TE: FIRST TIME THROUGH BRAKE CONTROL NOT DONE
REQA=0
RSPA=0
POS=0;' INITIAL BEAM ATTENUATOR FREQUENCY IS 0, PARKED IN THE BEAM
XQ #ATTEN,1
JS #THREAD0
EN
NO ----------------------------------------
#THREAD0
NO TE: THERE MUST BE A THREAD RUNNING FOR #LIMSWI, #TCPERR AND #ININT TO WORK
NO TE: CHECKS IF SPEEDS ARE ABOVE MAXIMUM ALLOWED
IF (_SPA>50000)
SPA=50000
ENDIF
IF (_SPB>50000)
SPB=50000
ENDIF
IF (_SPC>50000)
SPC=50000
ENDIF
IF (_SPD>200000)
SPD=200000
ENDIF
IF (_SPE>50000)
SPE=50000
ENDIF
IF (_SPF>100000)
SPF=100000
ENDIF
IF (_SPG>50000)
SPG=50000
ENDIF
NO IF (_SPH>50000)
NO SPH=50000
NO ENDIF
NO TE: TO CONTROL THE BRAKE ON BEAM SHADE RAISE AXIS
IF (_MOA=0)&(RSPA=0);'BEAM SHADE RAISE MOTOR IS ON
REQA=1
ENDIF
IF (_MOA=1)&(RSPA=1);'BEAM SHADE RAISE MOTOR IS ON
REQA=0
ENDIF
IF (REQA=1)&(RSPA=0);'BEAM SHADE RAISE MOTOR IS REQUIRED
SHA
WT 200
CB 9;'RELAY ON = BRAKE COIL ENERGISED = BRAKE DISENGAGED
WT 300
RSPA=1
ENDIF
IF (REQA=0)&(RSPA=1);'BEAM SHADE RAISE MOTOR IS NOT REQUIRED
SB 9;'RELAY OFF = BRAKE COIL DE-ENERGISED = BRAKE ENGAGED
WT 400
MOA
WT 100
RSPA=0
ENDIF
JP #THREAD0
EN
NO ----------------------------------------
#TCPERR
NO TE: EMPTY ROUTINE FOR A TCP ERROR
RE
NO ----------------------------------------
#ININT
NO TE: INTERUPT ROUTINE TO STOP ALL AXES
NO TE: WHEN SAFETY & INTERLOCK SYSTEM REQUESTS IT
STA,B,C,D,E,F,G,H
AM
MO
RI
NO ----------------------------------------
#LIMSWI
NO TE: LIMIT SWITCH ROUTINE WHICH SHORTENS DECEL TIME WHEN A LIMIT IS HIT
OLDDCA=_DCA;' REMEMBERS CURRENT DECEL
OLDDCB=_DCB
OLDDCC=_DCC
OLDDCD=_DCD
OLDDCE=_DCE
OLDDCF=_DCF
OLDDCG=_DCG
NO OLDDCH=_DCH
IF (_LFA = 0) | (_LRA = 0)
DCA=100000;' DECEL FOR LIMIT HIT OCCURENCE
STA
ENDIF
IF (_LFB = 0) | (_LRB = 0)
DCB=100000;' DECEL FOR LIMIT HIT OCCURENCE
STB
ENDIF
IF (_LFC = 0) | (_LRC = 0)
DCC=100000;' DECEL FOR LIMIT HIT OCCURENCE
STC
ENDIF
IF (_LFD = 0) | (_LRD = 0)
DCD=100000;' DECEL FOR LIMIT HIT OCCURENCE
STD
ENDIF
IF (_LFE = 0) | (_LRE = 0)
DCE=150000;' DECEL FOR LIMIT HIT OCCURENCE
STE
ENDIF
IF (_LFF = 0) | (_LRF = 0)
DCF=150000;' DECEL FOR LIMIT HIT OCCURENCE
STF
ENDIF
IF (_LFG = 0) | (_LRG = 0)
DCG=100000;' DECEL FOR LIMIT HIT OCCURENCE
STG
ENDIF
NO IF (_LFH = 0) | (_LRH = 0)
NO DCH=100000;' DECEL FOR LIMIT HIT OCCURENCE
NO STH
NO ENDIF
AM ABCDEFGH;' AFTER ALL AXES STOPPED
DCA=OLDDCA;' RESET DECEL TO OLD VALUE
DCB=OLDDCB
DCC=OLDDCC
DCD=OLDDCD
DCE=OLDDCE
DCF=OLDDCF
DCG=OLDDCG
NO DCH=OLDDCH
RE
NO ----------------------------------------
#ATTEN
NO TE: THIS IS A PROGRAM FOR CONTROLING THE BEAM ATTENUATOR
NO TE: ITS STATE IS SET BY THE VARIABLE POS
NO TE: IF POS=-1 THEN ITS OUT OF THE BEAM
NO TE: IF POS=0 THEN ITS IN THE BEAM, LIKE A SHUTTER
NO TE: IF POS=1 THEN ITS OSCILLATING
DEADBD=20
PARKPOS=8308518; 'PARKING ENCODER POSITION
SHUTPOS=8359718; 'BEAM SHUT ENCODER POSITION
STRTPOS=8395558; 'OSCILLATING START ENCODER POSITION
IF (POS=-1)&(@ABS[_TPD - PARKPOS]>DEADBD)
NO TE: PARK ATTENUATOR OUT OF BEAM - NO ATTENUATION
SPD=75000
ACD=50000
DCD=50000
SHD
PRD=(_TPD - PARKPOS)/8192*25000
BGD
AMD
MOD
ENDIF
IF (POS=0)&(@ABS[_TPD - SHUTPOS]>DEADBD)
NO TE: PARK ATTENUATOR IN BEAM - LIKE A SHUTTER
SPD=75000
ACD=50000
DCD=50000
SHD
PRD=(_TPD - SHUTPOS)/8192*25000
BGD
AMD
MOD
ENDIF
IF (POS=1)
NO TE: OSCILLATE ATTENUATOR
SHD
SPD=75000
ACD=50000
DCD=50000
PRD=(_TPD - STRTPOS)/8192*25000
BGD
AMD
SPD=180000
ACD=_SPD*4;' 0.25S TO ACCELERATE
DCD=_ACD
#LOOP
PRD=125000;' 80MM = 60MM IN THE BEAM, 10MM FOR ACCEL AND 10MM FOR DECEL
BGD
AMD
PRD=-125000
BGD
AMD
ENDIF
JP #LOOP,(POS=1)
JP #ATTEN
EN