#AUTO
NO TE: $Revision: 1.2 $
NO TE: $Date: 2006-11-01 06:04:09 $
NO TE: Author: Dan Bartlett
NO TE: Limit switch HOME routine added by Ferdi Franceschini
NO TE: Last revision by: $Author: ffr $
NO TE:
NO TE: A-SAMPLE UPPER TILT (sphi) - TILT 1
NO TE: B-SAMPLE LOWER TILT (schi) - TILT 2
NO TE: C-SAMPLE UPPER TRANSLATION (sz:nexus, sx:KDL) - LINEAR 1
NO TE: D-SAMPLE LOWER TRANSLATION (sx:nexus, sy:KDL) - LINEAR 2
NO TE: E-SAMPLE ROTATION (som) - ROTATE
NO TE: F-DETECTOR ROTATE
NO TE: G-SPARE
NO TE: H-SPARE
MT-2,-2,-2,-2,-2,-2,-2,-2;'CONFIGURES ALL AXES AS STEPPER
MO;' FIRST TIME MOTOR OFF
CN 1;' CONFIGURES LIMIT SWITCHES TO ACCEPT NC CONTACTS
II 8,,,0;' CONFIGURES THE 8TH INPUT TO ACTIVATE THE #ININT ROUTINE
OP 65280;' SETS OUTPUTS 9-16 ON = RELAYS OFF
IA 137,157,201,4;' CONFIGURES IP ADDRESS
AC 25000,25000,25000,25000,25000,15000,25000,25000;' SET ACELERATION
DC 25000,25000,25000,25000,25000,15000,25000,25000;' SET DECELERATION
SP 25000,25000,25000,25000,50000,150000,25000,25000;' SET SPEED
SIA=1,25,13,0<-1>2;'HEIDENHAIN ROQ425
SIB=1,25,13,0<-1>2;'HEIDENHAIN ROQ425
SIC=1,25,13,0<-1>2;'HEIDENHAIN ROQ425
SID=1,25,13,0<-1>2;'HEIDENHAIN ROQ425
SIE=1,25,13,0<-1>2;'HEIDENHAIN ROQ425
SIF=1,25,25,0<-1>2;'HEIDENHAIN RCN226
SIG=1,25,13,0<-1>2;'HEIDENHAIN ROQ425
SIH=1,25,13,0<-1>2;'HEIDENHAIN ROQ425
DONE=0;' FIRST TIME THROUGH AIRPAD CONTROL NOT DONE
JS #SOLCTRL
EN
#SOLCTRL
NO TE: CONTROLS THE AIRPAD SOLENOID VALVES
IF (_MOF=0);'DETECTOR MOTOR IS ON
SB 10;'DETECTOR AIR PAD OFF-SOLENOID OFF
CB 9;'DETECTOR AIR PAD ON-SOLENOID ON
DONE=0
ENDIF
IF (_MOF=1)&(DONE=0);'DETECTOR MOTOR IS OFF
SB 9;'DETECTOR AIR PAD ON-SOLENOID OFF
CB 10;'DETECTOR AIR PAD OFF-SOLENOID ON
WT500;'WAIT 1/2 SEC
SB 10;'DETECTOR AIR PAD OFF-SOLENOID OFF
DONE=1
ENDIF
JP #SOLCTRL
EN
#TCPERR
NO TE: EMPTY ROUTINE FOR A TCP ERROR
RE
#ININT
NO TE: INTERUPT ROUTINE TO STOP ALL AXES
NO TE: WHEN SAFETY & INTERLOCK SYSTEM REQUESTS IT
STA,B,C,D,E,F,G,H
AM
MO
RI
#LIMSWI
NO TE: LIMIT SWITCH ROUTINE WHICH SHORTENS DECEL TIME WHEN A LIMIT IS HIT
OLDDCA=_DCA;' REMEMBERS CURRENT DECEL
OLDDCB=_DCB
OLDDCC=_DCC
OLDDCD=_DCD
OLDDCE=_DCE
OLDDCF=_DCF
OLDDCG=_DCG
OLDDCH=_DCH
IF (_LFA = 0) | (_LRA = 0)
DCA=100000;' DECEL FOR LIMIT HIT OCCURENCE
STA
AMA
MOA
DCA=OLDDCA;' RESET DECEL TO OLD VALUE
ENDIF
IF (_LFB = 0) | (_LRB = 0)
DCB=100000;' DECEL FOR LIMIT HIT OCCURENCE
STB
AMB
MOB
DCB=OLDDCB;' RESET DECEL TO OLD VALUE
ENDIF
IF (_LFC = 0) | (_LRC = 0)
DCC=100000;' DECEL FOR LIMIT HIT OCCURENCE
STC
AMC
MOC
DCC=OLDDCC;' RESET DECEL TO OLD VALUE
ENDIF
IF (_LFD = 0) | (_LRD = 0)
DCD=100000;' DECEL FOR LIMIT HIT OCCURENCE
STD
AMD
MOD
DCD=OLDDCD;' RESET DECEL TO OLD VALUE
ENDIF
IF (_LFE = 0) | (_LRE = 0)
DCE=100000;' DECEL FOR LIMIT HIT OCCURENCE
STE
AME
MOE
DCE=OLDDCE;' RESET DECEL TO OLD VALUE
ENDIF
IF (_LFF = 0) | (_LRF = 0)
DCF=75000;' DECEL FOR LIMIT HIT OCCURENCE
STF
AMF
MOF
DCF=OLDDCF;' RESET DECEL TO OLD VALUE
ENDIF
IF (_LFG = 0) | (_LRG = 0)
DCG=100000;' DECEL FOR LIMIT HIT OCCURENCE
STG
AMG
MOG
DCG=OLDDCG;' RESET DECEL TO OLD VALUE
ENDIF
IF (_LFH = 0) | (_LRH = 0)
DCH=100000;' DECEL FOR LIMIT HIT OCCURENCE
STH
AMH
MOH
DCH=OLDDCH;' RESET DECEL TO OLD VALUE
ENDIF
RE