#AUTO
NO TE: $Revision: 1.4 $
NO TE: $Date: 2006-11-02 21:23:39 $
NO TE: Author: Dan Bartlett
NO TE: Limit switch HOME routine added by Ferdi Franceschini
NO TE: Last revision by: $Author: ffr $
NO TE:
NO TE: A-MONOCHROMATOR UPPER TILT (mphi) - TILT 1
NO TE: B-MONOCHROMATOR LOWER TILT (mchi) - TILT 2
NO TE: C-MONOCHROMATOR UPPER TRANSLATION (mz:nexus, mx:KDL) - LINEAR 1
NO TE: D-MONOCHROMATOR LOWER TRANSLATION (mx:nexus, my:KDL) - LINEAR 2
NO TE: E-MONOCHROMATOR ROTATION (mom) - ROTATE
NO TE: F-FLIGHT TUBE ROTATE
NO TE: G-PRIMARY COLLIMATOR 1
NO TE: H-PRIMARY COLLIMATOR 2
MT-2,-2,-2,-2,-2,-2,-2,-2;'CONFIGURES ALL AXES AS STEPPER
MO;' FIRST TIME MOTOR OFF
CN 1;' CONFIGURES LIMIT SWITCHES TO ACCEPT NC CONTACTS
II 8,,,0;' CONFIGURES THE 8TH INPUT TO ACTIVATE THE #ININT ROUTINE
OP 65280;' SETS OUTPUTS 9-16 ON = RELAYS OFF
IA 137,157,201,3;' CONFIGURES IP ADDRESS
AC 25000,25000,25000,25000,25000,10000,25000,25000;' SET ACELERATION
DC 25000,25000,25000,25000,25000,10000,25000,25000;' SET DECELERATION
SP 25000,25000,25000,25000,50000,100000,25000,25000;' SET SPEED
SIA=1,25,13,0<-1>2;'HEIDENHAIN ROQ425
SIB=1,25,13,0<-1>2;'HEIDENHAIN ROQ425
SIC=1,25,13,0<-1>2;'HEIDENHAIN ROQ425
SID=1,25,13,0<-1>2;'HEIDENHAIN ROQ425
SIE=1,25,13,0<-1>2;'HEIDENHAIN ROQ425
SIF=1,25,25,0<-1>2;'HEIDENHAIN RCN226
SIG=1,25,13,0<-1>2;'HEIDENHAIN ROQ425
SIH=1,25,13,0<-1>2;'HEIDENHAIN ROQ425
DONE=0;' FIRST TIME THROUGH AIRPAD CONTROL NOT DONE
JS #SOLCTRL
EN
#SOLCTRL
NO TE: CONTROLS THE AIRPAD SOLENOID VALVES
IF (_MOF=0);'FLIGHT TUBE MOTOR IS ON
SB 10;'SAMPLE STAGE AIR PAD OFF-SOLENOID OFF
SB 12;'DRIVE WHEEL UP-SOLENOID OFF
CB 9;'SAMPLE STAGE AIR PAD ON-SOLENOID ON
CB 11;'DRIVE WHEEL DOWN-SOLENOID ON
DONE=0
ENDIF
IF (_MOF=1)&(DONE=0);'FLIGHT TUBE MOTOR IS OFF
SB 9;'SAMPLE STAGE AIR PAD ON-SOLENOID OFF
SB 11;'DRIVE WHEEL DOWN-SOLENOID OFF
CB 10;'SAMPLE STAGE AIR PAD OFF-SOLENOID ON
CB 12;'DRIVE WHEEL UP-SOLENOID ON
WT500;'WAIT 1/2 SEC
SB 10;'SAMPLE STAGE AIR PAD OFF-SOLENOID OFF
SB 12;'DRIVE WHEEL UP-SOLENOID OFF
DONE=1
ENDIF
JP #SOLCTRL
EN
#TCPERR
NO TE: EMPTY ROUTINE FOR A TCP ERROR
RE
#ININT
NO TE: INTERUPT ROUTINE TO STOP ALL AXES
NO TE: WHEN SAFETY & INTERLOCK SYSTEM REQUESTS IT
STA,B,C,D,E,F,G,H
AM
MO
RI
#LIMSWI
NO TE: LIMIT SWITCH ROUTINE WHICH SHORTENS DECEL TIME WHEN A LIMIT IS HIT
OLDDCA=_DCA;' REMEMBERS CURRENT DECEL
OLDDCB=_DCB
OLDDCC=_DCC
OLDDCD=_DCD
OLDDCE=_DCE
OLDDCF=_DCF
OLDDCG=_DCG
OLDDCH=_DCH
IF (_LFA = 0) | (_LRA = 0)
DCA=100000;' DECEL FOR LIMIT HIT OCCURENCE
STA
AMA
MOA
DCA=OLDDCA;' RESET DECEL TO OLD VALUE
ENDIF
IF (_LFB = 0) | (_LRB = 0)
DCB=100000;' DECEL FOR LIMIT HIT OCCURENCE
STB
AMB
MOB
DCB=OLDDCB;' RESET DECEL TO OLD VALUE
ENDIF
IF (_LFC = 0) | (_LRC = 0)
DCC=100000;' DECEL FOR LIMIT HIT OCCURENCE
STC
AMC
MOC
DCC=OLDDCC;' RESET DECEL TO OLD VALUE
ENDIF
IF (_LFD = 0) | (_LRD = 0)
DCD=100000;' DECEL FOR LIMIT HIT OCCURENCE
STD
AMD
MOD
DCD=OLDDCD;' RESET DECEL TO OLD VALUE
ENDIF
IF (_LFE = 0) | (_LRE = 0)
DCE=100000;' DECEL FOR LIMIT HIT OCCURENCE
STE
AME
MOE
DCE=OLDDCE;' RESET DECEL TO OLD VALUE
ENDIF
IF (_LFF = 0) | (_LRF = 0)
DCF=50000;' DECEL FOR LIMIT HIT OCCURENCE
STF
AMF
MOF
DCF=OLDDCF;' RESET DECEL TO OLD VALUE
ENDIF
IF (_LFG = 0) | (_LRG = 0)
DCG=100000;' DECEL FOR LIMIT HIT OCCURENCE
STG
AMG
MOG
DCG=OLDDCG;' RESET DECEL TO OLD VALUE
ENDIF
IF (_LFH = 0) | (_LRH = 0)
DCH=100000;' DECEL FOR LIMIT HIT OCCURENCE
STH
AMH
MOH
DCH=OLDDCH;' RESET DECEL TO OLD VALUE
ENDIF
RE