#AUTO
NO TE: $Revision: 1.6 $
NO TE: $Date: 2006-11-02 02:49:04 $
NO TE: Author: Dan Bartlett
NO TE: Limit switch HOME routine added by Ferdi Franceschini
NO TE: Last revision by: $Author: dbx $
NO TE:
NO TE: A-SPARE
NO TE: B-SPARE
NO TE: C-SPARE
NO TE: D-SPARE
NO TE: E-SLIT 1 LEFT BLADE (ss1l)
NO TE: F-SLIT 1 RIGHT BLADE (ss1r)
NO TE: G-SLIT 1 TOP BLADE (ss1u)
NO TE: H-SLIT 1 BOTTOM BLADE (ss1d)
MT-2,-2,-2,-2,-2,-2,-2,-2;'CONFIGURES ALL AXES AS STEPPER
MO;' FIRST TIME MOTOR OFF
CN 1;' CONFIGURES LIMIT SWITCHES TO ACCEPT NC CONTACTS
II 8,,,0;' CONFIGURES THE 8TH INPUT TO ACTIVATE THE #ININT ROUTINE
IA 137,157,201,6;' CONFIGURES IP ADDRESS
AC ,,,,60000,60000,60000,60000;' SET ACELERATION
DC ,,,,60000,60000,60000,60000;' SET DECELERATION
SP ,,,,30000,30000,30000,30000;' SET SPEED
HOMERUN=0;' HOMING PROCEDURE HAS NOT BEEN RUN
JS #LOOPER;'RUNS THE LOOPING PROCEDURE
EN
#LOOPER
NO TE: ININT NEEDS A PROGRAM RUNNING TO WORK: JUST A LOOP
JP#LOOPER
EN
#TCPERR
NO TE: EMPTY ROUTINE FOR A TCP ERROR
RE
#ININT
NO TE: INTERUPT ROUTINE TO STOP ALL AXES
NO TE: WHEN SAFETY & INTERLOCK SYSTEM REQUESTS IT
STA,B,C,D,E,F,G,H
AM
MO
RI
#HOME
IF (HOMERUN = 1)
JP #ENDHOME
ENDIF
NO TE: MOVE SLIT FORWARD 10MM IF IT IS AGAINST THE REVERSE LIMIT SWITCH
IF ((_TSE & 4) = 0)
SHE
PRE=200000
BGE
ENDIF
NO TE: MOVE SLIT FORWARD 10MM IF IT IS AGAINST THE REVERSE LIMIT SWITCH
IF ((_TSF & 4) = 0)
SHF
PRF=200000
BGF
ENDIF
NO TE: MOVE SLIT FORWARD 10MM IF IT IS AGAINST THE REVERSE LIMIT SWITCH
IF ((_TSG & 4) = 0)
SHG
PRG=200000
BGG
ENDIF
NO TE: MOVE SLIT FORWARD 10MM IF IT IS AGAINST THE REVERSE LIMIT SWITCH
IF ((_TSH & 4) = 0)
SHH
PRH=200000
BGH
ENDIF
AMEFGH
NO TE: DRIVE ALL SLITS INTO REVERSE LIMIT SWITCH
SHEFGH
JG ,,,,-25000,-25000,-25000,-25000
BGEFGH
AMEFGH
NO TE: MOVE AWAY FROM SWITCHES BY 2MM AND DRIVE BACK SLOWLY
PR ,,,,80000,80000,80000,80000
BGEFGH
AMEFGH
JG,,,,-5000,-5000,-5000,-5000
BGEFGH
AMEFGH
NO TE: MOVE FORWARD FROM SWITCH BY 2MM AND SET ZERO
PR ,,,,40000,40000,40000,40000
BGEFGH
AMEFGH
DP ,,,,0,0,0,0
SP ,,,,30000,30000,30000,30000
HOMERUN=1
#ENDHOME
EN