#AUTO
NO TE: A-SAMPLE UPPER TILT (sphi) - TILT 1
NO TE: B-SAMPLE LOWER TILT (schi) - TILT 2
NO TE: C-SAMPLE UPPER TRANSLATION (sz:nexus, sx:KDL) - LINEAR 1
NO TE: D-SAMPLE LOWER TRANSLATION (sx:nexus, sy:KDL) - LINEAR 2
NO TE: E-SAMPLE ROTATION (som) - ROTATE
NO TE: F-DETECTOR ROTATE
NO TE: G-SPARE
NO TE: H-SPARE
MT-2,-2,-2,-2,-2,-2,-2,-2
MO
OP 65280
IA 137,157,201,67
CN 1
AC 25000,25000,25000,25000,25000,10000,25000,25000
DC 25000,25000,25000,25000,25000,10000,25000,25000
SP 25000,25000,25000,25000,25000,100000,25000,25000
SIA=1,25,13,0<-1>2
SIB=1,25,13,0<-1>2
SIC=1,25,13,0<-1>2
SID=1,25,13,0<-1>2
SIE=1,25,13,0<-1>2
SIF=1,25,25,0<-1>2
SIG=1,25,13,0<-1>2
SIH=1,25,13,0<-1>2
DONE=0
JS #SOLCTRL
EN
#SOLCTRL
IF (_MOF=0);'DETECTOR MOTOR IS ON
SB 10;'DETECTOR AIR PAD OFF-SOLENOID OFF
CB 9;'DETECTOR AIR PAD ON-SOLENOID ON
DONE=0
ENDIF
IF (_MOF=1)&(DONE=0);'DETECTOR MOTOR IS OFF
SB 9;'DETECTOR AIR PAD ON-SOLENOID OFF
CB 10;'DETECTOR AIR PAD OFF-SOLENOID ON
WT500;'WAIT 0.5SEC
SB 10;'DETECTOR AIR PAD OFF-SOLENOID OFF
DONE=1
ENDIF
JP #SOLCTRL
EN
#TCPERR
RE
#LIMSWI
OLDDCA=_DCA
OLDDCB=_DCB
OLDDCC=_DCC
OLDDCD=_DCD
OLDDCE=_DCE
OLDDCF=_DCF
OLDDCG=_DCG
OLDDCH=_DCH
IF (_LFA = 0) | (_LRA = 0)
DCA=100000
STA
AMA
MOA
DCA=OLDDCA
ENDIF
IF (_LFB = 0) | (_LRB = 0)
DCB=100000
STB
AMB
MOB
DCB=OLDDCB
ENDIF
IF (_LFC = 0) | (_LRC = 0)
DCC=100000
STC
AMC
MOC
DCC=OLDDCC
ENDIF
IF (_LFD = 0) | (_LRD = 0)
DCD=100000
STD
AMD
MOD
DCD=OLDDCD
ENDIF
IF (_LFE = 0) | (_LRE = 0)
DCE=100000
STE
AME
MOE
DCE=OLDDCE
ENDIF
IF (_LFF = 0) | (_LRF = 0)
DCF=30000
STF
AMF
MOF
DCF=OLDDCF
ENDIF
IF (_LFG = 0) | (_LRG = 0)
DCG=100000
STG
AMG
MOG
DCG=OLDDCG
ENDIF
IF (_LFH = 0) | (_LRH = 0)
DCH=100000
STH
AMH
MOH
DCH=OLDDCH
ENDIF
RE