NO TE: KOWARI - CONTROLLER 2
NO TE: 
NO TE: $Revision:
NO TE: $Name: not supported by cvs2svn $
NO TE: $Date: 2008-05-30 00:26:56 $
NO TE: Author: Dan Bartlett
NO TE: Last revision by: $Author: ffr $
NO TE:
NO TE: GALIL 31 BIT FIRMWARE IS REQUIRED FOR THIS CODE
NO TE: A-SAMPLE RAISE FIRST SECTION
NO TE: B-SAMPLE RAISE SECOND SECTION
NO TE: C-SAMPLE UPPER TRANSLATION
NO TE: D-SAMPLE LOWER TRANSLATION
NO TE: E-SAMPLE ROTATE
NO TE: F-DETECTOR ROTATE
NO TE: G-SPARE
NO TE: H-SPARE
NO ----------------------------------------
#AUTO
NO TE: THIS IS THE PROGRAM THAT RUNS AUTOMATICALLY ON CONTROLLER STARTUP
MT-2,-2,-2,-2,-2,-2,-2,-2;'CONFIGURES ALL AXES AS STEPPER
MO;' FIRST TIME MOTOR OFF
CN 1;' CONFIGURES LIMIT SWITCHES TO ACCEPT NC CONTACTS
II 8,,,0;' CONFIGURES THE 8TH INPUT TO ACTIVATE THE #ININT ROUTINE
OP 65280;' SETS OUTPUTS 9-16 ON = RELAYS OFF
IA 137,157,201,196;' CONFIGURES IP ADDRESS
AC 25000,,25000,25000,25000,25000,,;' SET ACELERATION
DC 25000,,25000,25000,25000,25000,,;' SET DECELERATION
SP 25000,,25000,25000,25000,25000,,;' SET SPEED
SIA=0;'TURN OFF CLOCK PULSES TO ALLOW ENCODER TO INITIALISE
SIB=0
SIC=0
SID=0
SIE=0
SIF=0
SIG=0
SIH=0
WT5000;'WAIT FOR ENCODER TO INITIALISE
SIA=1,25,13,0<12>2;'HEIDENHAIN ROQ425
SIC=1,25,13,0<12>2;'HEIDENHAIN ROQ425
SID=1,25,13,0<12>2;'HEIDENHAIN ROQ425
SIE=1,25,13,0<12>2;'HEIDENHAIN ROQ425
SIF=1,25,13,0<12>2;'HEIDENHAIN ROQ425
NO TE: FIRST TIME THROUGH MOTOR LINK NOT DONE
'REQA=0
'RSPA=0
'GAB=CA;'SET B FOLLOWS A IN COMMAND MODE
'GRB=1;' SET 1:1 GEARING FOR NOW
'GMB=1;' SET GANTRY MODE
NO TE: FIRST TIME THROUGH AIRPAD CONTROL NOT DONE
REQF=0
RSPF=0
JS #THREAD0
EN
NO ----------------------------------------
#THREAD0
NO TE: THERE MUST BE A THREAD RUNNING FOR #LIMSWI, #TCPERR AND #ININT TO WORK
NO TE: CHECKS IF SPEEDS ARE ABOVE MAXIMUM ALLOWED
IF (_SPA>200000)
SPA=200000
ENDIF
IF (_SPB>200000)
SPB=200000
ENDIF
IF (_SPC>50000)
SPC=50000
ENDIF
IF (_SPD>50000)
SPD=50000
ENDIF
IF (_SPE>50000)
SPE=50000
ENDIF
IF (_SPF>100000)
SPF=100000
ENDIF
IF (_SPG>50000)
SPG=50000
ENDIF
IF (_SPH>50000)
SPH=50000
ENDIF
NO TE: CONTROLS LINKED MOTORS
'IF (REQA=1)&(RSPA=0);' SAMPLE RAISE MOTOR IS REQUIRED
'SH AB;'TURN MOTOR ON
'RSPA=1
'ENDIF
'IF (REQA=0)&(RSPA=1);' SAMPLE RAISE MOTOR IS NOT REQUIRED
'MO AB;'TURN MOTOR OFF
'RSPA=0
'ENDIF
NO TE: CONTROLS THE AIRPAD SOLENOID VALVES
IF (REQF=1)&(RSPF=0);' DETECTOR ROTATE MOTOR IS REQUIRED
SH F;'TURN MOTOR ON
SB 10;'DETECTOR AIR PAD OFF-SOLENOID OFF
CB 9;'DETECTOR AIR PAD ON-SOLENOID ON
WT 1000;'WAIT FOR PADS TO LIFT
RSPF=1
ENDIF
IF (REQF=0)&(RSPF=1);' DETECTOR ROTATE MOTOR IS NOT REQUIRED
SB 9;'DETECTOR AIR PAD ON-SOLENOID OFF
CB 10;'DETECTOR AIR PAD OFF-SOLENOID ON
WT500;'WAIT 1/2 SEC
SB 10;'DETECTOR AIR PAD OFF-SOLENOID OFF
MO F;'TURN MOTOR OFF
RSPF=0
ENDIF
JP #THREAD0
EN
NO ----------------------------------------
#TCPERR
NO TE: EMPTY ROUTINE FOR A TCP ERROR
RE
NO ----------------------------------------
#ININT
NO TE: INTERUPT ROUTINE TO STOP ALL AXES
NO TE: WHEN SAFETY & INTERLOCK SYSTEM REQUESTS IT
STA,B,C,D,E,F,G,H
AM
MO
RI
NO ----------------------------------------
#LIMSWI
NO TE: LIMIT SWITCH ROUTINE WHICH SHORTENS DECEL TIME WHEN A LIMIT IS HIT
OLDDCA=_DCA;' REMEMBERS CURRENT DECEL
OLDDCB=_DCB
OLDDCC=_DCC
OLDDCD=_DCD
OLDDCE=_DCE
OLDDCF=_DCF
NO OLDDCG=_DCG;' COMMENTED OUT, AXIS NOT IN USE
NO OLDDCH=_DCH;' COMMENTED OUT, AXIS NOT IN USE
IF (_LFA = 0) | (_LRA = 0)
DCA=400000;' DECEL FOR LIMIT HIT OCCURENCE
STA
ENDIF
IF (_LFB = 0) | (_LRB = 0)
DCB=400000;' DECEL FOR LIMIT HIT OCCURENCE
STB
ENDIF
IF (_LFC = 0) | (_LRC = 0)
DCC=100000;' DECEL FOR LIMIT HIT OCCURENCE
STC
ENDIF
IF (_LFD = 0) | (_LRD = 0)
DCD=100000;' DECEL FOR LIMIT HIT OCCURENCE
STD
ENDIF
IF (_LFE = 0) | (_LRE = 0)
DCE=100000;' DECEL FOR LIMIT HIT OCCURENCE
STE
ENDIF
IF (_LFF = 0) | (_LRF = 0)
DCF=50000;' DECEL FOR LIMIT HIT OCCURENCE
STF
ENDIF
NO IF (_LFG = 0) | (_LRG = 0);' COMMENTED OUT, AXIS NOT IN USE
NO DCG=100000;' DECEL FOR LIMIT HIT OCCURENCE
NO STG
NO ENDIF
NO IF (_LFH = 0) | (_LRH = 0)
NO DCH=100000;' DECEL FOR LIMIT HIT OCCURENCE
NO STH
NO ENDIF
AM ABCDEF;' AFTER ALL AXES STOPPED
DCA=OLDDCA;' RESET DECEL TO OLD VALUE
DCB=OLDDCB
DCC=OLDDCC
DCD=OLDDCD
DCE=OLDDCE
DCF=OLDDCF
NO DCG=OLDDCG COMMENTED OUT, AXIS NOT IN USE
NO DCH=OLDDCH COMMENTED OUT, AXIS NOT IN USE
RE