NO TE: WOMBAT - CONTROLLER 1
NO TE:
NO TE: $Revision: 1.2 $
NO TE: $Date: 2007-01-31 03:39:19 $
NO TE: Author: Dan Bartlett
NO TE: Last revision by: $Author: dbx $
NO TE:
NO TE: A-MONOCHROMATOR UPPER TILT - TILT 1
NO TE: B-MONOCHROMATOR LOWER TILT - TILT 2
NO TE: C-MONOCHROMATOR UPPER TRANSLATION - LINEAR 1
NO TE: D-MONOCHROMATOR LOWER TRANSLATION - LINEAR 2
NO TE: E-MONOCHROMATOR ROTATION - ROTATE
NO TE: F-FLIGHT TUBE ROTATE
NO TE: G-SPARE
NO TE: H-SPARE
NO ----------------------------------------
#AUTO
NO TE: THIS IS THE PROGRAM THAT RUNS AUTOMATICALLY ON CONTROLLER STARTUP
MT-2,-2,-2,-2,-2,-2,-2,-2;'CONFIGURES ALL AXES AS STEPPER
MO;' FIRST TIME MOTOR OFF
CN 1;' CONFIGURES LIMIT SWITCHES TO ACCEPT NC CONTACTS
II 8,,,0;' CONFIGURES THE 8TH INPUT TO ACTIVATE THE #ININT ROUTINE
OP 65280;' SETS OUTPUTS 9-16 ON = RELAYS OFF
IA 137,157,201,67;' CONFIGURES IP ADDRESS
AC 25000,25000,25000,25000,50000,10000,25000,25000;' SET ACELERATION
DC 25000,25000,25000,25000,50000,10000,25000,25000;' SET DECELERATION
SP 25000,25000,25000,25000,25000,100000,25000,25000;' SET SPEED
SIA=1,25,13,0<-2>2;'HEIDENHAIN ROQ425
SIB=1,25,13,0<-2>2;'HEIDENHAIN ROQ425
SIC=1,25,13,0<-2>2;'HEIDENHAIN ROQ425
SID=1,25,13,0<-2>2;'HEIDENHAIN ROQ425
SIE=1,25,13,0<-2>2;'HEIDENHAIN ROQ425
SIF=1,25,25,0<-2>2;'HEIDENHAIN RCN226
SIG=0,25,13,0<-2>2;'NOT USED
SIH=0,25,13,0<-2>2;'NOT USED
APDONE=0;' FIRST TIME THROUGH AIRPAD CONTROL NOT DONE
JS #THREAD0
EN
NO ----------------------------------------
#THREAD0
NO TE: THERE MUST BE A THREAD RUNNING FOR #LIMSWI, #TCPERR AND #ININT TO WORK
NO TE: CHECKS IF SPEEDS ARE ABOVE MAXIMUM ALLOWED
IF (_SPA>50000)
SPA=50000
ENDIF
IF (_SPB>50000)
SPB=50000
ENDIF
IF (_SPC>50000)
SPC=50000
ENDIF
IF (_SPD>50000)
SPD=50000
ENDIF
IF (_SPE>50000)
SPE=50000
ENDIF
IF (_SPF>100000)
SPF=100000
ENDIF
NO IF (_SPG>50000) AXES NOT USED, COMMENTED OUT
NO SPG=50000
NO ENDIF
NO IF (_SPH>50000)
NO SPH=50000
NO ENDIF
NO TE: CONTROLS THE AIRPAD SOLENOID VALVES
IF (_MOF=0);'FLIGHT TUBE MOTOR IS ON
SB 10;'SAMPLE STAGE AIR PAD OFF-SOLENOID OFF
SB 12;'DRIVE WHEEL UP-SOLENOID OFF
CB 9;'SAMPLE STAGE AIR PAD ON-SOLENOID ON
CB 11;'DRIVE WHEEL DOWN-SOLENOID ON
APDONE=0
ENDIF
IF (_MOF=1)&(APDONE=0);'FLIGHT TUBE MOTOR IS OFF
SB 9;'SAMPLE STAGE AIR PAD ON-SOLENOID OFF
SB 11;'DRIVE WHEEL DOWN-SOLENOID OFF
CB 10;'SAMPLE STAGE AIR PAD OFF-SOLENOID ON
CB 12;'DRIVE WHEEL UP-SOLENOID ON
WT500;'WAIT 1/2 SEC
SB 10;'SAMPLE STAGE AIR PAD OFF-SOLENOID OFF
SB 12;'DRIVE WHEEL UP-SOLENOID OFF
APDONE=1
ENDIF
JP #THREAD0
EN
NO ----------------------------------------
#TCPERR
NO TE: EMPTY ROUTINE FOR A TCP ERROR
RE
NO ----------------------------------------
#ININT
NO TE: INTERUPT ROUTINE TO STOP ALL AXES
NO TE: WHEN SAFETY & INTERLOCK SYSTEM REQUESTS IT
STA,B,C,D,E,F,G,H
AM
MO
RI
NO ----------------------------------------
#LIMSWI
NO TE: LIMIT SWITCH ROUTINE WHICH SHORTENS DECEL TIME WHEN A LIMIT IS HIT
OLDDCA=_DCA;' REMEMBERS CURRENT DECEL
OLDDCB=_DCB
OLDDCC=_DCC
OLDDCD=_DCD
OLDDCE=_DCE
OLDDCF=_DCF
NO OLDDCG=_DCG AXIS NOT USED
NO OLDDCH=_DCH AXIS NOT USED
IF (_LFA = 0) | (_LRA = 0)
DCA=100000;' DECEL FOR LIMIT HIT OCCURENCE
STA
ENDIF
IF (_LFB = 0) | (_LRB = 0)
DCB=100000;' DECEL FOR LIMIT HIT OCCURENCE
STB
ENDIF
IF (_LFC = 0) | (_LRC = 0)
DCC=100000;' DECEL FOR LIMIT HIT OCCURENCE
STC
ENDIF
IF (_LFD = 0) | (_LRD = 0)
DCD=100000;' DECEL FOR LIMIT HIT OCCURENCE
STD
ENDIF
IF (_LFE = 0) | (_LRE = 0)
DCE=100000;' DECEL FOR LIMIT HIT OCCURENCE
STE
ENDIF
IF (_LFF = 0) | (_LRF = 0)
DCF=50000;' DECEL FOR LIMIT HIT OCCURENCE
STF
ENDIF
NO IF (_LFG = 0) | (_LRG = 0) AXES NOT USED, COMMENTED OUT
NO DCG=100000;' DECEL FOR LIMIT HIT OCCURENCE
NO STG
NO ENDIF
NO IF (_LFH = 0) | (_LRH = 0)
NO DCH=100000;' DECEL FOR LIMIT HIT OCCURENCE
NO STH
NO ENDIF
AM ABCDEFGH;' AFTER ALL AXES STOPPED
DCA=OLDDCA;' RESET DECEL TO OLD VALUE
DCB=OLDDCB
DCC=OLDDCC
DCD=OLDDCD
DCE=OLDDCE
DCF=OLDDCF
NO DCG=OLDDCG AXIS NOT USED
NO DCH=OLDDCH AXIS NOT USED
RE