cmake_minimum_required(VERSION 3.03)

project(cfd950 VERSION 0.1)

add_compile_options(
  -Wall
  -Wformat=2
  -Wno-format-nonliteral
  -Wno-strict-aliasing
  -Wuninitialized
  -Wno-unused-function
)

option(
  BUILD_FRONTEND
  "If ON, build the default frontend executable"
  OFF
)

set(CMAKE_PREFIX_PATH "$ENV{MIDASSYS}")
find_package(Midas REQUIRED)

set(
  DRIVERS
  $ENV{MIDASSYS}/drivers/bus/null.cxx
  $ENV{MIDASSYS}/drivers/class/generic.cxx
)

################################################################################
## Device Library
################################################################################

add_library(
  cfd950
  device/cfd950.cxx
  ${DRIVERS}
)

set_property(
  TARGET
    cfd950
  PROPERTY
    CXX_STANDARD 11
)

target_include_directories(
  cfd950
  PUBLIC
    $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/device>
    $<INSTALL_INTERFACE:include>
)

target_link_libraries(
  cfd950
  PUBLIC
    pthread
    util
    rt
    dl
    midas::midas
    midas::mscb
)

################################################################################
## Test Frontend
################################################################################

if(${BUILD_FRONTEND})

  add_executable(
    cfd950_fe
    frontend/cfd950_scfe.cxx
  )

  set_property(
    TARGET
      cfd950_fe
    PROPERTY
      CXX_STANDARD 11
  )

  target_include_directories(
    cfd950_fe
    PRIVATE
      $ENV{MIDASSYS}/drivers
  )

  target_link_libraries(
    cfd950_fe
    PRIVATE
      cfd950
      midas::mfe
  )

endif()
