cmake_minimum_required(VERSION 3.03)

project(bulk_monitor VERSION 0.1)

add_compile_options(
  -Wall
  -Wformat=2
  -Wno-format-nonliteral
  -Wno-strict-aliasing
  -Wuninitialized
  -Wno-unused-function
)

option(
  BUILD_FRONTEND
  "If ON, build the default frontend executable"
  OFF
)

set(CMAKE_PREFIX_PATH "$ENV{MIDASSYS}")
find_package(Midas REQUIRED)

set(
  DRIVERS
  $ENV{MIDASSYS}/drivers/class/generic.cxx
)

set(SYS_LIBS
    pthread
    util
    rt
    dl
)

set(MIDAS_LIBS
    midas::mfe
    midas::midas
)

set(LIBS ${SYS_LIBS} ${MIDAS_LIBS})

################################################################################
## Device Library
################################################################################

add_library(
  bulk_monitor
  device/bulk_monitor.cxx
  frontend/musr_midas.cxx
  ${DRIVERS}
)

set_property(
  TARGET
    bulk_monitor
  PROPERTY
    CXX_STANDARD 11
)

target_include_directories(
  bulk_monitor
  PUBLIC
    ${CMAKE_CURRENT_SOURCE_DIR}
  PRIVATE
    $ENV{MIDASSYS}/drivers
)

target_link_libraries(
  bulk_monitor
  ${LIBS}
)

target_compile_definitions(
  bulk_monitor
  PRIVATE
  OMIT_MUSR_FE=1
)

################################################################################
## Test Frontend
################################################################################

if(${BUILD_FRONTEND})

  add_executable(
    bulk_monitor_fe
    frontend/bulk_monitor_scfe.cxx
  )

  set_property(
    TARGET
      bulk_monitor_fe
    PROPERTY
      CXX_STANDARD 11
  )

  target_include_directories(
    bulk_monitor_fe
    PRIVATE
      $ENV{MIDASSYS}/drivers
  )

  target_link_libraries(
    bulk_monitor_fe
    bulk_monitor
  )

endif()
