Qt5 built in qwt (#570)

- qt4->qt5
- in built qt5 6.1.5 because rhel7 is not upto date with qt5, removed findqwt.cmake
- made a fix in qwt lib (qwt_plot_layout.h) to work with 5.15 and lower versions for qrect constr.
- qt5 forms fixed, qt4 many hard coding forms switched to forms including qtabwidget, scrolls etc, fonts moved to forms
 - docking option enabled by default, removed option to disable docking feature from "Mode"
- added qVersionResolve utility functions to handle compatibility before and after qt5.12
- qtplots (ian's code) takes in gain mode enable to set some settings within the class, with proper gain plot ticks
- ensure gain plots have no zooming of z axis in 2d and y axis in 1d
- removed placeholder text in qpalette in main window form as its not supportd until 5.12 (so using qt5.9 designer insted of qt5.15 to cope)
- tab order
Servers:
- fixed some error messages that were empty for fail in funcs (mostly minor as if this error, major issues)

libs/qwt-6.1.5/features/qwtfunctions.pri

@@ -0,0 +1,94 @@
+################################################################
+# Qwt Widget Library
+# Copyright (C) 1997   Josef Wilgen
+# Copyright (C) 2002   Uwe Rathmann
+#
+# This library is free software; you can redistribute it and/or
+# modify it under the terms of the Qwt License, Version 1.0
+################################################################
+
+# Copied and modified from qt_functions.prf
+
+defineReplace(qwtLibraryTarget) {
+
+    unset(LIBRARY_NAME)
+    LIBRARY_NAME = $$1
+
+    mac:contains(QWT_CONFIG, QwtFramework) {
+
+        QMAKE_FRAMEWORK_BUNDLE_NAME = $$LIBRARY_NAME
+        export(QMAKE_FRAMEWORK_BUNDLE_NAME)
+    }
+
+    contains(TEMPLATE, .*lib):CONFIG(debug, debug|release) {
+
+        !debug_and_release|build_pass {
+
+            mac:RET = $$member(LIBRARY_NAME, 0)_debug
+            win32:RET = $$member(LIBRARY_NAME, 0)d
+        }
+    }
+
+    isEmpty(RET):RET = $$LIBRARY_NAME
+    return($$RET)
+}
+
+defineTest(qwtAddLibrary) {
+
+    LIB_PATH = $$1
+    LIB_NAME = $$2
+
+    mac:contains(QWT_CONFIG, QwtFramework) {
+
+        LIBS      *= -F$${LIB_PATH}
+    }
+    else {
+
+        unix:lessThan(QT_MAJOR_VERSION, 5) {
+
+            # Many Linux distributions install Qwt in the same directory
+            # as the Qt libs and thus we need to prepend the path for the local build
+            # to avoid conflicting with the installed version.
+            # Qt5 qmake appends ( instead of prepending ) the path to the Qt libs
+            # to LIBS, but for Qt4 we need to use the QMAKE_LIBDIR_FLAGS.
+
+            QMAKE_LIBDIR_FLAGS *= -L$${LIB_PATH}
+        }
+        else {
+            LIBS *= -L$${LIB_PATH}
+        }
+    }
+
+    unset(LINKAGE)
+
+    mac:contains(QWT_CONFIG, QwtFramework) {
+
+        LINKAGE = -framework $${LIB_NAME}
+    }
+
+    isEmpty(LINKAGE) {
+
+        if(!debug_and_release|build_pass):CONFIG(debug, debug|release) {
+
+            mac:LINKAGE = -l$${LIB_NAME}_debug
+            win32:LINKAGE = -l$${LIB_NAME}d
+        }
+    }
+
+    isEmpty(LINKAGE) {
+
+        LINKAGE = -l$${LIB_NAME}
+    }
+
+    !isEmpty(QMAKE_LSB) {
+
+        QMAKE_LFLAGS *= --lsb-shared-libs=$${LIB_NAME}
+    }
+
+    LIBS += $$LINKAGE
+    export(LIBS)
+    export(QMAKE_LFLAGS)
+    export(QMAKE_LIBDIR_FLAGS)
+
+    return(true)
+}