mirror of
https://github.com/slsdetectorgroup/slsDetectorPackage.git
synced 2025-06-23 18:17:59 +02:00
Qt5 built in qwt (#570)
- qt4->qt5 - in built qt5 6.1.5 because rhel7 is not upto date with qt5, removed findqwt.cmake - made a fix in qwt lib (qwt_plot_layout.h) to work with 5.15 and lower versions for qrect constr. - qt5 forms fixed, qt4 many hard coding forms switched to forms including qtabwidget, scrolls etc, fonts moved to forms - docking option enabled by default, removed option to disable docking feature from "Mode" - added qVersionResolve utility functions to handle compatibility before and after qt5.12 - qtplots (ian's code) takes in gain mode enable to set some settings within the class, with proper gain plot ticks - ensure gain plots have no zooming of z axis in 2d and y axis in 1d - removed placeholder text in qpalette in main window form as its not supportd until 5.12 (so using qt5.9 designer insted of qt5.15 to cope) - tab order Servers: - fixed some error messages that were empty for fail in funcs (mostly minor as if this error, major issues)
This commit is contained in:
Dhanya Thattil
37
libs/qwt-6.1.5/features/qwt.prf
Normal file
37
libs/qwt-6.1.5/features/qwt.prf
Normal file
@ -0,0 +1,37 @@
|
||||
################################################################
|
||||
# Qwt Widget Library
|
||||
# Copyright (C) 1997 Josef Wilgen
|
||||
# Copyright (C) 2002 Uwe Rathmann
|
||||
#
|
||||
# This library is free software; you can redistribute it and/or
|
||||
# modify it under the terms of the Qwt License, Version 1.0
|
||||
################################################################
|
||||
|
||||
include ( ./qwtconfig.pri )
|
||||
include ( ./qwtfunctions.pri )
|
||||
|
||||
contains(QWT_CONFIG, QwtDll) {
|
||||
|
||||
DEFINES *= QWT_DLL
|
||||
}
|
||||
|
||||
contains(QWT_CONFIG, QwtSvg) {
|
||||
|
||||
QT *= svg
|
||||
}
|
||||
else {
|
||||
|
||||
DEFINES *= QWT_NO_SVG
|
||||
}
|
||||
|
||||
contains(QWT_CONFIG, QwtFramework) {
|
||||
|
||||
INCLUDEPATH *= $${QWT_INSTALL_LIBS}/qwt.framework/Headers
|
||||
}
|
||||
else {
|
||||
|
||||
INCLUDEPATH *= $${QWT_INSTALL_HEADERS}
|
||||
}
|
||||
|
||||
# QMAKE_RPATHDIR *= $${QWT_INSTALL_LIBS}
|
||||
qwtAddLibrary($${QWT_INSTALL_LIBS}, qwt)
|
||||
175
libs/qwt-6.1.5/features/qwtconfig.pri
Normal file
175
libs/qwt-6.1.5/features/qwtconfig.pri
Normal file
@ -0,0 +1,175 @@
|
||||
################################################################
|
||||
# Qwt Widget Library
|
||||
# Copyright (C) 1997 Josef Wilgen
|
||||
# Copyright (C) 2002 Uwe Rathmann
|
||||
#
|
||||
# This library is free software; you can redistribute it and/or
|
||||
# modify it under the terms of the Qwt License, Version 1.0
|
||||
################################################################
|
||||
|
||||
QWT_VER_MAJ = 6
|
||||
QWT_VER_MIN = 1
|
||||
QWT_VER_PAT = 5
|
||||
QWT_VERSION = $${QWT_VER_MAJ}.$${QWT_VER_MIN}.$${QWT_VER_PAT}
|
||||
|
||||
######################################################################
|
||||
# Install paths
|
||||
######################################################################
|
||||
|
||||
QWT_INSTALL_PREFIX = $$[QT_INSTALL_PREFIX]
|
||||
|
||||
unix {
|
||||
QWT_INSTALL_PREFIX = /usr/local/qwt-$$QWT_VERSION
|
||||
# QWT_INSTALL_PREFIX = /usr/local/qwt-$$QWT_VERSION-qt-$$QT_VERSION
|
||||
}
|
||||
|
||||
win32 {
|
||||
QWT_INSTALL_PREFIX = C:/Qwt-$$QWT_VERSION
|
||||
# QWT_INSTALL_PREFIX = C:/Qwt-$$QWT_VERSION-qt-$$QT_VERSION
|
||||
}
|
||||
|
||||
QWT_INSTALL_DOCS = $${QWT_INSTALL_PREFIX}/doc
|
||||
QWT_INSTALL_HEADERS = $${QWT_INSTALL_PREFIX}/include
|
||||
QWT_INSTALL_LIBS = $${QWT_INSTALL_PREFIX}/lib
|
||||
|
||||
######################################################################
|
||||
# Designer plugin
|
||||
# creator/designer load designer plugins from certain default
|
||||
# directories ( f.e the path below QT_INSTALL_PREFIX ) and the
|
||||
# directories listed in the QT_PLUGIN_PATH environment variable.
|
||||
# When using the path below QWT_INSTALL_PREFIX you need to
|
||||
# add $${QWT_INSTALL_PREFIX}/plugins to QT_PLUGIN_PATH in the
|
||||
# runtime environment of designer/creator.
|
||||
######################################################################
|
||||
|
||||
QWT_INSTALL_PLUGINS = $${QWT_INSTALL_PREFIX}/plugins/designer
|
||||
|
||||
# linux distributors often organize the Qt installation
|
||||
# their way and QT_INSTALL_PREFIX doesn't offer a good
|
||||
# path. Also QT_INSTALL_PREFIX is only one of the default
|
||||
# search paths of the designer - not the Qt creator
|
||||
|
||||
#QWT_INSTALL_PLUGINS = $$[QT_INSTALL_PREFIX]/plugins/designer
|
||||
|
||||
######################################################################
|
||||
# Features
|
||||
# When building a Qwt application with qmake you might want to load
|
||||
# the compiler/linker flags, that are required to build a Qwt application
|
||||
# from qwt.prf. Therefore all you need to do is to add "CONFIG += qwt"
|
||||
# to your project file and take care, that qwt.prf can be found by qmake.
|
||||
# ( see http://doc.trolltech.com/4.7/qmake-advanced-usage.html#adding-new-configuration-features )
|
||||
# I recommend not to install the Qwt features together with the
|
||||
# Qt features, because you will have to reinstall the Qwt features,
|
||||
# with every Qt upgrade.
|
||||
######################################################################
|
||||
|
||||
QWT_INSTALL_FEATURES = $${QWT_INSTALL_PREFIX}/features
|
||||
# QWT_INSTALL_FEATURES = $$[QT_INSTALL_PREFIX]/features
|
||||
|
||||
######################################################################
|
||||
# Build the static/shared libraries.
|
||||
# If QwtDll is enabled, a shared library is built, otherwise
|
||||
# it will be a static library.
|
||||
######################################################################
|
||||
|
||||
QWT_CONFIG += QwtDll
|
||||
|
||||
######################################################################
|
||||
# QwtPlot enables all classes, that are needed to use the QwtPlot
|
||||
# widget.
|
||||
######################################################################
|
||||
|
||||
QWT_CONFIG += QwtPlot
|
||||
|
||||
######################################################################
|
||||
# QwtWidgets enables all classes, that are needed to use the all other
|
||||
# widgets (sliders, dials, ...), beside QwtPlot.
|
||||
######################################################################
|
||||
|
||||
QWT_CONFIG += QwtWidgets
|
||||
|
||||
######################################################################
|
||||
# If you want to display svg images on the plot canvas, or
|
||||
# export a plot to a SVG document
|
||||
######################################################################
|
||||
|
||||
#QWT_CONFIG += QwtSvg
|
||||
|
||||
######################################################################
|
||||
# If you want to use a OpenGL plot canvas
|
||||
######################################################################
|
||||
|
||||
QWT_CONFIG += QwtOpenGL
|
||||
|
||||
######################################################################
|
||||
# You can use the MathML renderer of the Qt solutions package to
|
||||
# enable MathML support in Qwt. Because of license implications
|
||||
# the ( modified ) code of the MML Widget solution is included and
|
||||
# linked together with the QwtMathMLTextEngine into an own library.
|
||||
# To use it you will have to add "CONFIG += qwtmathml"
|
||||
# to your qmake project file.
|
||||
######################################################################
|
||||
|
||||
#QWT_CONFIG += QwtMathML
|
||||
|
||||
######################################################################
|
||||
# If you want to build the Qwt designer plugin,
|
||||
# enable the line below.
|
||||
# Otherwise you have to build it from the designer directory.
|
||||
######################################################################
|
||||
|
||||
#QWT_CONFIG += QwtDesigner
|
||||
|
||||
######################################################################
|
||||
# Compile all Qwt classes into the designer plugin instead
|
||||
# of linking it against the shared Qwt library. Has no effect
|
||||
# when QwtDesigner or QwtDll are not both enabled.
|
||||
#
|
||||
# On systems where rpath is supported ( all Unixoids ) the
|
||||
# location of the installed Qwt library is compiled into the plugin,
|
||||
# but on Windows it might be easier to have a self contained
|
||||
# plugin to avoid any hassle with configuring the runtime
|
||||
# environment of the designer/creator.
|
||||
######################################################################
|
||||
|
||||
win32 {
|
||||
QWT_CONFIG += QwtDesignerSelfContained
|
||||
}
|
||||
|
||||
######################################################################
|
||||
# If you want to auto build the examples, enable the line below
|
||||
# Otherwise you have to build them from the examples directory.
|
||||
######################################################################
|
||||
|
||||
#QWT_CONFIG += QwtExamples
|
||||
|
||||
######################################################################
|
||||
# The playground is primarily intended for the Qwt development
|
||||
# to explore and test new features. Nevertheless you might find
|
||||
# ideas or code snippets that help for application development
|
||||
# If you want to auto build the applications in playground, enable
|
||||
# the line below.
|
||||
# Otherwise you have to build them from the playground directory.
|
||||
######################################################################
|
||||
|
||||
#QWT_CONFIG += QwtPlayground
|
||||
|
||||
######################################################################
|
||||
# When Qt has been built as framework qmake wants
|
||||
# to link frameworks instead of regular libs
|
||||
######################################################################
|
||||
|
||||
macx:!static:CONFIG(qt_framework, qt_framework|qt_no_framework) {
|
||||
|
||||
QWT_CONFIG += QwtFramework
|
||||
}
|
||||
|
||||
######################################################################
|
||||
# Create and install pc files for pkg-config
|
||||
# See http://www.freedesktop.org/wiki/Software/pkg-config/
|
||||
######################################################################
|
||||
|
||||
unix {
|
||||
|
||||
#QWT_CONFIG += QwtPkgConfig
|
||||
}
|
||||
94
libs/qwt-6.1.5/features/qwtfunctions.pri
Normal file
94
libs/qwt-6.1.5/features/qwtfunctions.pri
Normal file
@ -0,0 +1,94 @@
|
||||
################################################################
|
||||
# Qwt Widget Library
|
||||
# Copyright (C) 1997 Josef Wilgen
|
||||
# Copyright (C) 2002 Uwe Rathmann
|
||||
#
|
||||
# This library is free software; you can redistribute it and/or
|
||||
# modify it under the terms of the Qwt License, Version 1.0
|
||||
################################################################
|
||||
|
||||
# Copied and modified from qt_functions.prf
|
||||
|
||||
defineReplace(qwtLibraryTarget) {
|
||||
|
||||
unset(LIBRARY_NAME)
|
||||
LIBRARY_NAME = $$1
|
||||
|
||||
mac:contains(QWT_CONFIG, QwtFramework) {
|
||||
|
||||
QMAKE_FRAMEWORK_BUNDLE_NAME = $$LIBRARY_NAME
|
||||
export(QMAKE_FRAMEWORK_BUNDLE_NAME)
|
||||
}
|
||||
|
||||
contains(TEMPLATE, .*lib):CONFIG(debug, debug|release) {
|
||||
|
||||
!debug_and_release|build_pass {
|
||||
|
||||
mac:RET = $$member(LIBRARY_NAME, 0)_debug
|
||||
win32:RET = $$member(LIBRARY_NAME, 0)d
|
||||
}
|
||||
}
|
||||
|
||||
isEmpty(RET):RET = $$LIBRARY_NAME
|
||||
return($$RET)
|
||||
}
|
||||
|
||||
defineTest(qwtAddLibrary) {
|
||||
|
||||
LIB_PATH = $$1
|
||||
LIB_NAME = $$2
|
||||
|
||||
mac:contains(QWT_CONFIG, QwtFramework) {
|
||||
|
||||
LIBS *= -F$${LIB_PATH}
|
||||
}
|
||||
else {
|
||||
|
||||
unix:lessThan(QT_MAJOR_VERSION, 5) {
|
||||
|
||||
# Many Linux distributions install Qwt in the same directory
|
||||
# as the Qt libs and thus we need to prepend the path for the local build
|
||||
# to avoid conflicting with the installed version.
|
||||
# Qt5 qmake appends ( instead of prepending ) the path to the Qt libs
|
||||
# to LIBS, but for Qt4 we need to use the QMAKE_LIBDIR_FLAGS.
|
||||
|
||||
QMAKE_LIBDIR_FLAGS *= -L$${LIB_PATH}
|
||||
}
|
||||
else {
|
||||
LIBS *= -L$${LIB_PATH}
|
||||
}
|
||||
}
|
||||
|
||||
unset(LINKAGE)
|
||||
|
||||
mac:contains(QWT_CONFIG, QwtFramework) {
|
||||
|
||||
LINKAGE = -framework $${LIB_NAME}
|
||||
}
|
||||
|
||||
isEmpty(LINKAGE) {
|
||||
|
||||
if(!debug_and_release|build_pass):CONFIG(debug, debug|release) {
|
||||
|
||||
mac:LINKAGE = -l$${LIB_NAME}_debug
|
||||
win32:LINKAGE = -l$${LIB_NAME}d
|
||||
}
|
||||
}
|
||||
|
||||
isEmpty(LINKAGE) {
|
||||
|
||||
LINKAGE = -l$${LIB_NAME}
|
||||
}
|
||||
|
||||
!isEmpty(QMAKE_LSB) {
|
||||
|
||||
QMAKE_LFLAGS *= --lsb-shared-libs=$${LIB_NAME}
|
||||
}
|
||||
|
||||
LIBS += $$LINKAGE
|
||||
export(LIBS)
|
||||
export(QMAKE_LFLAGS)
|
||||
export(QMAKE_LIBDIR_FLAGS)
|
||||
|
||||
return(true)
|
||||
}
|
||||
Reference in New Issue
Block a user