$ set noverify
$!==============================================================================
$! Author: Anselm Hofer
$!
$! Commandoprozedur fuer das Erstellen von Dateien 'CODENUMMERN.LIST', welche
$! die von ACCEL bzw. MUTRACK verwendeten Code-Nummern fuer Integrationsgebiet
$! und Teilchenchicksal erstellen. Diese Dateien werden nach den Directories
$! ACCEL$SOURCEdirectory bzw. MUTRACK$SOURCEdirectory kopiert und koennen von
$! VMS-Ebene oder von PAW aus mittels 'ACCODE' bzw. 'MUCODE' ausgegeben werden.
$! 
$! Der Aufruf dieser Prozedur fuer das Erstellen der Dateien geschieht ueber
$! MAKEACCODE / MAKEMUCODE.
$!==============================================================================
$ progr = P1		! = 'MUTRACK' oder 'ACCEL'
$ ext   = P2		! = '_MU' oder '_AC'
$ flag  = P3		! = 'MAKE' oder 'TYPE'
$!==============================================================================
$ sourceFile = "mutrack$COMdirectory:MAKE_CODENUMMERN-LIST.FOR."
$ objectFile = "''progr'$COMdirectory:MAKE''ext'_CODENUMMERN-LIST.OBJ"
$ exeFile  = "''progr'$COMdirectory:MAKE''ext'_CODENUMMERN-LIST.EXE"
$ listFile = "''progr'$SOURCEdirectory:CODENUMMERN.LIST"
$!==============================================================================
$ if p3.EQS."MAKE" then goto make
$ if p3.EQS."TYPE" then goto type
$ if p3.EQS." " then write sys$output "missing parameter P3 (""MAKE"" or ""TYPE"")"
$ write sys$output "unknown parameter P3: ''P3'"
$!==============================================================================
$ MAKE:
$! Compilieren und Linken des Programms fuer den Ausdruck der Liste (muss
$! jedesmal neu gemacht werden, damit die Liste wirklich die aktuellen Code-
$! Nummern enthaelt):
$! 
$ archi = F$GETSYI("ARCH_NAME")    ! Host OS either "VAX" or "Alpha"
$ if archi .EQS. "VAX" then options = " "
$ if archi .EQS. "Alpha" then options = " /ali=all"
$
$ define MAKE_CODENUMMERN_INCFILE1 "''progr'$SOURCEdirectory:COM_''progr'.INC"
$ define MAKE_CODENUMMERN_INCFILE2 "''progr'$SOURCEdirectory:INITIALIZE.INC"
$ set verify
$ fortran 'sourceFile' /object='objectFile' 'options'
$ link 'objectFile' /exe='exeFile'
$ set noverify
$
$ del 'objectFile'.* /nocon
$ pu 'exeFile'
$ deassign MAKE_CODENUMMERN_INCFILE1
$ deassign MAKE_CODENUMMERN_INCFILE2
$
$! Erstellen der Liste durch Aufruf des Programms:
$ tmp == F$TRNLNM("''progr'$SOURCEdirectory")
$ define MAKE_CODENUMMERN_OUTDIR  "''TMP'"
$ run 'exeFile'
$ deassign MAKE_CODENUMMERN_OUTDIR
$ purge 'listFile'
$
$ EXIT
$!==============================================================================
$ TYPE:
$! Ausgabe der Liste:
$ TYPE 'listFile'
$ EXIT
$!==============================================================================