Added to repository.

mutrack/com/PLOT_BATCH_STATUS.COM

@@ -0,0 +1,85 @@
+$ SET NOVERIFY
+$! P1 = 'PROGR' = PROGRAMMNAME			= "MUTRACK" bzw. "ACCEL"
+$! P2 = KUERZEL					= "MU"      bzw. "AC"
+$! P3 = OBTIONALER TEIL DES PROGRAMMAUFRUFES	= "TRACK"   bzw. "CEL"
+$!==============================================================================
+$!	LAEUFT 'PROGR' ALS BATCHJOB, SO WIRD (BEI MEHR ALS EINER SCHLEIFE)
+$!	DER AKTUELLE NAME DER AUSGABEDATEIEN SOWIE DIE NUMMER DER GERADE 
+$!	ABGEARBEITETEN SCHLEIFE IN EINER DATEI "''PROGR'.MESSAGE" ABGELEGT.
+$!	MIT DER VORLIEGENDEN KOMMANDOPROZEDUR WIRD DIESE INFORMATION AUS
+$!	DER .MESSAGE-DATEI AUSGELESEN UND AUF DEN BILDSCHIRM GEGEBEN.
+$!	AH, 12-JUN-1996
+$!==============================================================================
+$ SET NOVERIFY
+$ SET ON
+$ SAY := WRITE SYS$OUTPUT
+$ SHOW TIME
+$
+$ MAXLISTINDX = 20
+$
+$ FLAG = 0
+$ NOTLASTTIME = 1
+$ listIndx = 1
+$ ON ERROR THEN GOTO READERROR
+$
+$ LOOP:
+$ messageName = "SYS$SCRATCH:''P2'_LIST''listIndx'.MESSAGE"
+$
+$ FILEOPEN:
+$ OPEN/READ/SHARE=WRITE/ERROR=next messagefile 'messageName'
+$ flag = 1
+$ SAY "================================================================================"
+$ IF NOTLASTTIME THEN READ messagefile NUMMER
+$ READ messagefile TIME1
+$ READ messagefile INPUTNAME
+$ READ messagefile FILENAME
+$ READ messagefile LOOPINFO
+$ READ messagefile TIME2
+$ CLOSE messagefile
+$ IF NOTLASTTIME
+$	THEN
+$	SAY "JOB SUBMITTED WITH ""SUB''P2'LIST ''listIndx'"":"
+$ ELSE
+$	SAY "JOB SUBMITTED WITH ""SUB''P2'*''P3'"":"
+$ ENDIF
+$ SAY "  NAME OF INPUT FILE  : ''INPUTNAME'"
+$ IF NOTLASTTIME
+$	THEN
+$	SAY "  (''NUMMER'. file in input_file list,''TIME1')"
+$ ELSE
+$	SAY "  (''TIME1')"
+$ ENDIF
+$ SAY "  NAME OF OUTPUT FILES: ''FILENAME'"
+$ LOOPINFO = LOOPINFO-"  "
+$ SAY " ''LOOPINFO'"
+$ SAY "  (''TIME2')"
+$ GOTO next
+$ !
+$ READERROR:
+$ SAY "reading ''messageName'"
+$ CLOSE messagefile
+$ !
+$ NEXT:
+$ IF listIndx.LE.maxListIndx
+$	THEN
+$	listIndx = listIndx + 1
+$	IF listIndx.LE.maxListIndx
+$		THEN
+$		GOTO LOOP
+$	ELSE
+$		messageName = "SYS$SCRATCH:''P1'.MESSAGE
+$		NOTLASTTIME = 0
+$		GOTO FILEOPEN
+$	ENDIF
+$ ELSE
+$	IF FLAG.EQ.0
+$		THEN
+$		SAY "  THERE ARE NO APPROPRIATE ''P2'*.MESSAGE-FILES IN SYS$SCRATCH"
+$	ELSE
+$		SAY "================================================================================"
+$		SAY "  ( -> SYS$SCRATCH:''P2'*.MESSAGE )"
+$	ENDIF
+$ ENDIF
+$ !
+$ SAY "================================================================================"
+$ EXIT