# main cmake file for nonlocal
#
# author: Andreas Suter, andreas.suter@psi.ch

cmake_minimum_required(VERSION 3.17)
project(nonlocal)

# set version number
set(nonlocal_VERSION_MAJOR 0)
set(nonlocal_VERSION_MINOR 1)

# configure a header file to pass some of the CMake settings to the source code
configure_file(
  "${PROJECT_SOURCE_DIR}/nonlocalConfig.h.in"
  "${PROJECT_BINARY_DIR}/nonlocalConfig.h"
)

include(GNUInstallDirs)

# CERN/ROOT related stuff
find_package(ROOT 6.18 REQUIRED COMPONENTS MathMore)
include(${ROOT_USE_FILE})

# GSL related stuff
find_package(GSL REQUIRED)

# Eigen related stuff
find_path(EIGEN_INCLUDE_DIR
  NAMES Eigen/Dense
  PATHS /opt/eigen /usr/include/eigen3 /usr/local/include/eigen3
)
if(NOT EIGEN_INCLUDE_DIR)
  message(WARNING "Eigen headers not found; build may fail if Eigen is required.")
endif()

# FFTW3 related stuff
find_package(PkgConfig REQUIRED)
pkg_check_modules(FFTW3 REQUIRED fftw3)

add_library(pippard PPippard.cpp PPippard.h)
target_include_directories(pippard
  PRIVATE
    "${PROJECT_BINARY_DIR}"
    ${ROOT_INCLUDE_DIRS}
    ${GSL_INCLUDE_DIRS}
    ${EIGEN_INCLUDE_DIR}
    ${FFTW3_INCLUDE_DIRS}
)

add_executable(nonlocal nonlocal.cpp)
target_include_directories(nonlocal
  PRIVATE
    "${PROJECT_BINARY_DIR}"
    ${ROOT_INCLUDE_DIRS}
    ${GSL_INCLUDE_DIRS}
    ${EIGEN_INCLUDE_DIR}
    ${FFTW3_INCLUDE_DIRS}
)
target_link_libraries(nonlocal
  PRIVATE
    pippard
    GSL::gsl
    GSL::gslcblas
    ${ROOT_LIBRARIES}
    ${FFTW3_LIBRARIES}
)

# install stuff
set(CMAKE_INSTALL_PREFIX $ENV{HOME})
install(TARGETS nonlocal RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})

# uninstall target
configure_file(
  "${CMAKE_CURRENT_SOURCE_DIR}/cmake_uninstall.cmake.in"
  "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
  IMMEDIATE @ONLY)

add_custom_target(uninstall
  COMMAND ${CMAKE_COMMAND} -P ${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake)
