# - Class_MuSR_PSI library ----------------------------------------------------

#--- create pkg-config info ---------------------------------------------------
set(prefix "${CMAKE_INSTALL_PREFIX}")   
set(exec_prefix "\$\{prefix\}")
set(libdir "\$\{exec_prefix\}/lib")
set(includedir "\$\{prefix\}/include")   
set(PSIBIN_VERSION "0.2.0")
set(PSIBIN_LIBRARY_NAME "Class_MuSR_PSI")
configure_file("Class_MuSR_PSI.pc.in" "Class_MuSR_PSI.pc" @ONLY)

#--- lib creation -------------------------------------------------------------
add_library(Class_MuSR_PSI SHARED MuSR_td_PSI_bin.cpp)

#--- OS dependent pre-compiler settings for PSI-BIN ---------------------------
if (${CMAKE_SYSTEM_NAME} STREQUAL "Linux")
  target_compile_definitions(Class_MuSR_PSI PRIVATE __linux__)
elseif (${CMAKE_SYSTEM_NAME} STREQUAL "Darwin")
  target_compile_definitions(Class_MuSR_PSI PRIVATE _Darwin_)
elseif (${CMAKE_SYSTEM_NAME} STREQUAL "Windows")
  target_compile_definitions(Class_MuSR_PSI PRIVATE _WIN32)
endif (${CMAKE_SYSTEM_NAME} STREQUAL "Linux")

#--- set target properties, e.g. version --------------------------------------
set_target_properties(Class_MuSR_PSI
  PROPERTIES
    VERSION ${PSIBIN_VERSION}
)

#--- install Class_MuSR_PSI solib ---------------------------------------------
install(TARGETS Class_MuSR_PSI EXPORT musrfitTargets DESTINATION ${CMAKE_INSTALL_LIBDIR})

#--- install MuSR_td_PSI_bin header -------------------------------------------
install(FILES MuSR_td_PSI_bin.h DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})

#--- install pkg-config info --------------------------------------------------
install(
  FILES ${CMAKE_CURRENT_BINARY_DIR}/Class_MuSR_PSI.pc
  DESTINATION ${CMAKE_INSTALL_LIBDIR}/pkgconfig
)
